XL 2016 Demande d'aide sur un tableau excel

Function TotalMois(mois, Agent$, Plage As Range, Total As Range)
Dim i&, j&
mois = Month("1/" & mois)
Set Plage = Plage.Resize(Plage(Plage.Rows.Count).End(xlUp).Row, 1)
For i = 1 To Plage.Count
    If IsDate(Plage(i)) Then If Month(Plage(i)) = mois Then Exit For
Next i
For j = i + 1 To Plage.Count
    If IsDate(Plage(j)) Then Exit For
    If Plage(j) = Agent Then TotalMois = Intersect(Plage(j).EntireRow, Total): Exit For
Next j
If TotalMois = 0 Then TotalMois = "" 'masque les zéros
End Function

=TotalMois(B$1;$A2;Data!$A:$A;Data!$AG:$AG)

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$S$2" Or Target(1) = "" Then Exit Sub
Dim mois%
Application.ScreenUpdating = False
If Target <> "TOUT" Then
    mois = Month("1/" & Target)
    Imprimer mois
Else
    For mois = 1 To 12
        Imprimer mois
    Next mois
End If
End Sub

Sub Imprimer(mois%)
Dim derlig&, i&, j&
With Sheets("Data")
    derlig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 1 To derlig
        If IsDate(.Cells(i, 1)) Then
            If Month(.Cells(i, 1)) = mois Then
                For j = i + 1 To derlig
                    If LCase(.Cells(j, 1)) = "validation planning" Then
                        .PageSetup.PrintArea = .Range(.Cells(i, 1), .Cells(j, "AG")).Address
                        .PrintPreview 'pour afficher l'aperçu avant impression
                        '.PrintOut 'pour imprimer
                        Exit For
                    End If
                Next j
            End If
        End If
    Next i
End With
End Sub