Autres Création de tableau à partir d'une Macro

[Pickis]

Bonjour,
Peut on avec une Macro créer un tableau, qui reprend le nom de dossier sous forme de colonne, et que le contenu des colonnes comprenne le contenu des dossiers.
En gros passer de ca :

a ca :

 

[job75]

Bonjour Pickis,

On peut avec cette macro :

Sub Listes()
Dim chemin$, dossier, col%, dos, lig&, fichier$, ligTotal&
chemin = ThisWorkbook.Path & "\" 'à adapter
dossier = Array("01 CP", "02 CE1", "03 CE2", "04 CM1", "05 CM2") 'tableau adaptable
Application.ScreenUpdating = False
Cells.Delete 'RAZ
col = 1
For Each dos In dossier
    col = col + 1
    Cells(1, col) = dos
    lig = 2
    fichier = Dir(chemin & dos & "\*.jpg") 'recherche des fichiers JPEG
    While fichier <> ""
        Cells(lig, col) = UCase(fichier)
        lig = lig + 1
        fichier = Dir
    Wend
    If lig > ligTotal Then ligTotal = lig
Next
Cells(ligTotal, 1) = "Total"
Cells(ligTotal, 2).Resize(, col - 1) = "=COUNTA(R1C:R[-1]C)-1"
Columns.AutoFit 'ajustement largeur
End Sub

Les dossiers listés doivent être dans le dossier du fichier de la macro.

A+

 

[Pickis]

Ok je viens de tester c'est formidable.
Par contre mes dossiers change de nom suivant les écoles, et parfois j'ai plus ou moins de classe.
Est il possible du coup que cela marche? car pour tester j'ai rajouter une classe et elle n'apparait pas dans le tableau.

 

[job75]

Comme je l'ai indiqué il vous faut adapter la ligne de code dossier = Array(xxx)

Je vous conseille de créer une feuille pour chaque école.

 

[Pickis]

OK merci Beaucoup.
👍👍👍👍

 

[job75]

Pour l'école Jules Ferry vous utiliserez :

dossier = Array("Jules Ferry CP", "Jules Ferry CE1", "Jules Ferry CE2", "Jules Ferry CM1", "Jules Ferry CM2") 'tableau adaptable

Pour une autre école remplacer Jules Ferry par son nom.