XL 2013 Copier des données dans une base de données dont la dernière ligne change tous les mois

Hasco à dit:

Bonjour,

Voici une proposition qui le fait.
Par contre je n'ai pas su où trouver "Sep 21" dans votre feuille BDD
Dans votre feuille ALL RM ce ne sont pas des dates en colonne B mais des textes 'Aug 21' ????
Evitez de mettre des espaces blancs en fin de noms de vos feuilles 'BDD ' , 'ALL RM ' vous vous faciliterez le travail ultérieur.

VB:

Sub Maj()
    Const Formule As String = "=IFERROR(G@/F@,0)"
    Dim Bdd As Range, Destination As Range
    Dim nbLignes As Long
    '
    ' toutes les données de bdd
    With ThisWorkbook.Sheets("BDD   ").Range("B6").CurrentRegion
        Set Bdd = .Offset(2).Resize(.Rows.Count - 2)
    End With
    '
    ' nombre de lignes
    nbLignes = Bdd.Rows.Count
    '
    ' destination des nouvelles données
    With ThisWorkbook.Sheets("ALL RM").Range("B1").CurrentRegion
        '
        ' Ligne suivante du tableau, retaillée au nombre de lignes
        With .Offset(.Rows.Count).Resize(nbLignes)
            ' Transfert des valeurs.
            .Columns(1).Value = "Sep 21"
            .Columns(2).Resize(, 3).Value = Bdd.Columns(2).Resize(, 3).Value
            .Columns(5).Value = Bdd.Columns(6).Value
            .Columns(6).Value = Bdd.Columns(8).Value
            .Columns(7).Formula = Replace(Formule, "@", .Row)
        End With

    End With

End Sub

Dernier point, quand vous voulez une macro, mettez un fichier .xlsm et pas .xlsx

Cordialement

Cliquez pour agrandir...

Hasco à dit:

Bonjour,

Voici

Cliquez pour agrandir...