XL 2013 Comment trouver le 2e chiffre d'une suite de chiffre à l'aide d'une formule (sans VBA)

Catoux

XLDnaute Nouveau
Bonjour,

j'aimerais savoir comment dire à Excel de me trouver le 2e chiffre d'une suite de chiffre dans une même cellule!

Exemple:
1628706469719.png

J'aimerais qu'à l'aide d'une formule, je sois capable de faire ressortir le chiffre 95,7 dans la case B1, le chiffre 3,9 dans la case B2 et le chiffre 98,6 dans la colonne B3.
Il s'agit du 2e chiffre de chaque case en A.

Merci infiniment pour votre aide!
 

Pièces jointes

  • 2e chiffre de la colonne A.xlsx
    8 KB · Affichages: 13
Dernière édition:

job75

XLDnaute Barbatruc
Bonsoir Catoux, JFL_Excel, laurent950, Phil69970,

Sélectionner A1 et définir les noms espace1 et espace2 :
Code:
=TROUVE(" ";SUPPRESPACE(Feuil1!$A1))+1
=TROUVE(" ";SUPPRESPACE(Feuil1!$A1)&" ";espace1)
Formule en B2 à tirer vers le bas :
Code:
=SIERREUR(--STXT(SUPPRESPACE(A1);espace1;espace2-espace1);"")
A+
 

Pièces jointes

  • 2e chiffre de la colonne A(1).xlsx
    9.9 KB · Affichages: 8

JFL_XLD

XLDnaute Junior
Bonjour à tous !

Pour tenir compte de l'éventuel besoin de décimales supplémentaires, je vous livre ma formule amendée :
VB:
=CNUM(STXT(A1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";2))-(CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1)))

Cordialement,

JF
 

Dudu2

XLDnaute Barbatruc
Bonjour à tous,

Allez, encore une petite pour la route:
VB:
=STXT(STXT(A1;CHERCHE(" ";A1)+1;100);1;CHERCHE(" ";STXT(A1;CHERCHE(" ";A1)+1;100))-1)

Et s'il le faut en numérique:
Code:
=CNUM(STXT(STXT(A1;CHERCHE(" ";A1)+1;100);1;CHERCHE(" ";STXT(A1;CHERCHE(" ";A1)+1;100))-1))
 

Discussions similaires

Statistiques des forums

Discussions
313 316
Messages
2 097 098
Membres
106 836
dernier inscrit
ChristopheDF