XL 2013 Comment trouver le 2e chiffre d'une suite de chiffre à l'aide d'une formule (sans VBA)

[Catoux]

Bonjour,

j'aimerais savoir comment dire à Excel de me trouver le 2e chiffre d'une suite de chiffre dans une même cellule!

Exemple:

J'aimerais qu'à l'aide d'une formule, je sois capable de faire ressortir le chiffre 95,7 dans la case B1, le chiffre 3,9 dans la case B2 et le chiffre 98,6 dans la colonne B3.
Il s'agit du 2e chiffre de chaque case en A.

Merci infiniment pour votre aide!

 

[JFL_XLD]

Bonsoir !

Une proposition en B1 :

=CNUM(STXT(A1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1))

A tirer vers le bas.

Cordialement,

JF

 

[laurent950]

Bonsoir

=CNUM(GAUCHE(DROITE(A4;NBCAR(A4)-NBCAR(GAUCHE(A4;CHERCHE(" ";A4))));CHERCHE(" ";DROITE(A4;NBCAR(A4)-NBCAR(GAUCHE(A4;CHERCHE(" ";A4)))))))

 

[Phil69970]

Bonjour @Catoux
edit :Bonjpur @JFL_Excel , @laurent950

Je te propose ce fichier.

*Merci de ton retour et n’oublie pas de passer le sujet en résolu

@Phil69970

 

[Phil69970]

Re

*la solution de JF ne donne qu'un chiffre après la virgule par contre celle de Laurent ou la mienne fonctionne correctement

@Phil69970

 

[job75]

Bonsoir Catoux, JFL_Excel, laurent950, Phil69970,

Sélectionner A1 et définir les noms espace1 et espace2 :

=TROUVE(" ";SUPPRESPACE(Feuil1!$A1))+1
=TROUVE(" ";SUPPRESPACE(Feuil1!$A1)&" ";espace1)

Formule en B2 à tirer vers le bas :

=SIERREUR(--STXT(SUPPRESPACE(A1);espace1;espace2-espace1);"")

A+

 

[JFL_XLD]

Bonjour à tous !

Pour tenir compte de l'éventuel besoin de décimales supplémentaires, je vous livre ma formule amendée :

=CNUM(STXT(A1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";2))-(CHERCHE("µ";SUBSTITUE(A1;" ";"µ";1))+1)))

Cordialement,

JF

 

[Dudu2]

Bonjour à tous,

Allez, encore une petite pour la route:

=STXT(STXT(A1;CHERCHE(" ";A1)+1;100);1;CHERCHE(" ";STXT(A1;CHERCHE(" ";A1)+1;100))-1)

Et s'il le faut en numérique:

=CNUM(STXT(STXT(A1;CHERCHE(" ";A1)+1;100);1;CHERCHE(" ";STXT(A1;CHERCHE(" ";A1)+1;100))-1))

 

[JFL_XLD]

Bonjour de nouveau !

Pour le plaisir (et un chouia plus court ) :

=CNUM(STXT(A1;TROUVE(" ";A1)+1;TROUVE(" ";STXT(A1;TROUVE(" ";A1)+1;100))))

Cordialement,

JF