Microsoft 365 colonne numéros manquants

[perrmi]

bonjour a vous tous
la pluie revient 🙂
un petit problème pour moi mais pour vous je pense que c'est enfantin 🙂
2 colonnes avec des numéros
a la suite de l'une d'entre elle j'aimerais faire apparaitre les numéros manquant de la 1ere colonne
voir fichier
avec mes remerciements
perrmi

 

[Hasco]

Bonjour,

Avec excel 365 et +, la fonction Filtre en D12 :

=FILTRE($C$4:$C$22;($C$4:$C$22<>"")*ESTNA(EQUIV($C$4:$C$22;$D$4:$D$11;0)))

Excel à partir de 2010, la fonction agregat en E12 à tirer vers le bas:

SIERREUR(AGREGAT(15;6;$C$4:$C$22/($C$4:$C$22<>"")/ESTNA(EQUIV($C$4:$C$22;$D$4:$D$11;0));LIGNE(1:1));""

 

[Simply]

Bonjour,

=FILTRE(C4:C19;NB.SI(D4:D11;C4:C19)=0;"")

 

[perrmi]

Bonjour,

Avec excel 365 et +, la fonction Filtre en D12 :

alors la bravo 🙂
magnifique
je vous remercie beaucoup de votre rapidité de de votre connaissance d'Excel
bonne soirée
perrmi

 

[Hasco]

Re

Je viens de modifier le fichier joint précédement avec une nouvelle fonction pour ceux qui n'auraient pas excel 365

 

[mapomme]

Bonsoir à tous 😉,
Moi aussi je veux jouer 😜.

Pour O365, la formule suivante en D12 qui trie en ordre décroissant:

=TRIER(FILTRE(C4:C19;ESTNA(EQUIV(C4:C19;D4:D11;0)));;-1)

Mettre 1 à la place de -1 pour un tri en ordre croissant.