cellules vides et format en export SAP

[babass78]

Bonjour,

J'ai un fichier exporté de SAP Business One

1)° Dans les colonnes B, C et L, (en jaune) j'aimerai que les données de la ligne se répètent jusqu'au client suivant

- code client
- nom du client
- code mode de paiement

Lorsque je sélectionne la colonne, F5 Atteindre cellules vides, il ne se passe rien

Comment pourrais-je faire?

2°) Comment faire pour que les dates soient des dates ?colonnes G et H (quand on fait F2, cela se met en date et à droite)

3) Quand une cellule de la colonne D est vide(en orange), je souhaiterai que la ligne entière soit supprimée.

Est-il possible d’avoir une macro qui fasse les 3 points en même temps ?

Merci de votre aide

 

[Iznogood1]

Re : cellules vides et format en export SAP

Bonjour, le code suivant devrait faire l'affaire :

Option Explicit

Sub MiseEnForme()
  Dim r As Range
  Dim CodeClient As String
  Dim NomClient As String
  Dim Mode As String
  Dim nbLi As Long, i As Long
  
  nbLi = Feuil1.[A2].CurrentRegion.Rows.Count
  
  'Copie et Format
  For Each r In Feuil1.Range("A2:A" & nbLi)
    'Recopie des valeurs
    If r.Offset(0, 1).Value <> "" Then
      CodeClient = r.Offset(0, 1).Value
      NomClient = r.Offset(0, 2).Value
      Mode = r.Offset(0, 11).Value
    Else
      r.Offset(0, 1).Value = CodeClient
      r.Offset(0, 2).Value = NomClient
      r.Offset(0, 11).Value = Mode
    End If
    'Converstion des dates
    On Error Resume Next
      r.Offset(0, 6).Value = CDate(r.Offset(0, 6).Value)
      r.Offset(0, 7).Value = CDate(r.Offset(0, 7).Value)
    On Error GoTo 0
  Next r
  
  'Suppression
  For i = nbLi To 2 Step -1
    If Feuil1.Range("D" & i).Value = "" Then Feuil1.Range("D" & i).EntireRow.Delete
  Next i
End Sub

 

[babass78]

Re : cellules vides et format en export SAP

merci beaucoup je vais la tester