Calculer un nombre de valeurs uniques

billy2000 · 3 Août 2011

Bonjour,

Le problème est certainement simple pour la plupart d'entre vous! Mais pas pour moi! Merci d'avance à toutes les personnes qui pourront m'aider.

Voila mon problème:
J'ai une liste de visiteurs globale à partir de laquelle je souhaiterais calculer le nombre de visiteurs uniques (ne comptabiliser les personnes qu'une fois si celles-ci sont venues plusieurs fois). Il y a une colonne Noms et une colonne Prénoms. Je transmets un petit fichier pour une meilleure compréhension.
Existe-t-il une formule magique?

Merci à tous,

JBOBO · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

Bonjour,

En D8 :

=B8&C8

en E8 :

=SI(D8="";"";NB.SI($D$8: D8;D8))

Les 2 à tirer vers le bas, puis pour le résultat en E6 par exemple,

=NB.SI(E8:E19;1)

hoerwind · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

Bonjour,

Essaie cette formule :
=SOMMEPROD((1/NB.SI(C8:C17;C8:C17)))

billy2000 · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

ça marche! Mille mercis à tous les 2!

BOISGONTIER · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

Bonjour,

Voir PJ

Le champ comporte des cellules vides

=NB(1/FREQUENCE(EQUIV(noms&prénoms;noms&prénoms;0);LIGNE(INDIRECT("1:"&LIGNES(noms)))))

JB

david84 · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

Bonjour tout le monde,
une autre possibilité :

Code:

=SOMME(N(FREQUENCE(EQUIV(noms&prénoms;noms&prénoms;0);EQUIV(noms&prénoms;noms&prénoms;0))>0))

Validation classique
A+

Monique · 3 Août 2011

Re : Calculer un nombre de valeurs uniques

Bonjour,

Sans les blancs :
=NB(SI(noms&prénoms<>"";1/FREQUENCE(EQUIV(noms&prénoms;noms&prénoms;0);LIGNE(INDIRECT("1:"&LIGNES(noms))))))

Calculer un nombre de valeurs uniques

billy2000

XLDnaute Nouveau

Pièces jointes

JBOBO

XLDnaute Accro

hoerwind

XLDnaute Barbatruc

billy2000

XLDnaute Nouveau

BOISGONTIER

XLDnaute Barbatruc

Pièces jointes

david84

XLDnaute Barbatruc

Monique

Nous a quitté

Discussions similaires