Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

[rere67]

Bonjour,

Je vais vous exposer mon problème.

J'ai un tableau avec différentes situations qui sont visualisés ou à contrôler et parfois des situations se trouvent dans les deux cas.

J'aimerais pouvoir faire un récapitulatif de ce tableau et savoir combien de fois j'ai chaque combinaison.

Vu que je ne sias pas si j'étais clair je vous joint un fichier reprenant mon idée.

J'espère que vous avez la solution 🙂

Je vous remercie par avance

 

[Dranreb]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour.
En F2:

=SOMMEPROD(N($A$2:$A$11=GAUCHE($E2;1));N(DECALER($B$2:$B$11;0;DROITE($E2;9)="contrôler")="x"))

Propagé vers le bas.
Cordialement.

Edit : Salut dihc@R 🙂

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour,
en F2,

=SOMMEPROD((A$2:A$11=GAUCHE(E2))*(B$1:C$1=STXT(E2;TROUVE("-";E2)+2;99))*(B$2:C$11="X"))

@ tirer vers le bas
@ micalement

Edit : Salut bernarD 🙂

 

[ted13]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Le décompte multi-critères peut se faire avec la fonction NB.SI.ENS.

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour ted13 et Bienvenu sur XLD,

Le décompte multi-critères peut se faire avec la fonction NB.SI.ENS.

tu peux nous montrer comment???
Amicalement

 

[job75]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour rere67, salut Bernard, R@chid, ted13,

ted13 a parfaitement raison pour NB.SI.ENS, voir fichier joint.

Mais bien sûr c'est pour Excel 2007 et versions suivantes.

A+

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour @ tous,
Bonjour Job75,
Oui je sais, je l'ai pour lui faire apprendre de présenter la solution complète pas les outils @ utiliser...

=NB.SI.ENS(A:A;GAUCHE(E2);DECALER(A:A;;EQUIV(STXT(E2;TROUVE("-";E2)+2;25);B$1:C$1;0));"X")

@ micalement

 

[rere67]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour,

Merci pour votre aide car cela marche très bien.

Par contre j'ai un peu modifié les termes A, B, C par du texte exemple "Prise de commande" ou "Mise à jour à effectuer"

Comment peux-t-on modifié la formule pour que ça marche dans ce cas de figure également ?

Merci à vous

rere67

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour,
il faut mettre les modifications sur le fichier, pour qu'on puisse bien voir...
Amicalement

 

[rere67]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour,

Voici le fichier avec les modifications que j'ai apporté.

Merci à vous.

Bonne journée.

rere67

 

[job75]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour,

En F2, à tirer vers le bas :

=SOMMEPROD(ESTNUM(CHERCHE(A$2:A$11;E2))*(DECALER(B$2:B$11;;ESTNUM(CHERCHE(C$1;E2)))="X"))

Avec CHERCHE la casse n'a pas d'importance.

Fichier joint.

A+

 

[job75]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Re,

La solution précédente suppose qu'en colonne E on trouve soit "visualisé" soit "A contrôler".

Si ce n'est pas toujours le cas utiliser en F2 :

=SOMMEPROD(ESTNUM(CHERCHE(A$2:A$11;E2))*(DECALER(A$2:A$11;;ESTNUM(CHERCHE(B$1;E2))+2*ESTNUM(CHERCHE(C$1;E2)))="X"))

Fichier (2).

A+

 

[job75]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Re,

La solution du fichier (2) est plus parlante avec ce fichier (3) :

=SOMMEPROD(ESTNUM(CHERCHE(A$2:A$11;F2))*(DECALER(A$2:A$11;;ESTNUM(CHERCHE(B$1;F2))+2*ESTNUM(CHERCHE(C$1;F2))+3*ESTNUM(CHERCHE(D$1;F2)))="X"))

Edit : s'il y avait plus de colonnes B C D... à traiter, voir le fichier (3 bis) avec cette formule :

=SOMMEPROD(ESTNUM(CHERCHE(A$2:A$11;F2))*(DECALER(A$2:A$11;;EQUIV(STXT(F2;CHERCHE("-";F2)+2;50);B$1:D$1;0))="X"))

A+

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonjour @ tous,
Salut Job75,
une autre non matricielle, mais elle nécessite un tri croissant ou décroissant sur la première colonne...
en F2 @ tirer vers le bas,

=NB.SI(DECALER(A$1;EQUIV(GAUCHE(E2;TROUVE("-";E2)-2);A$2:A$11;0);EQUIV(STXT(E2;TROUVE("-";E2)+2;25);B$1:C$1;0);NB.SI(A$2:A$11;GAUCHE(E2;TROUVE("-";E2)-2)));"X")

Voir PJ...

Amicalement

 

[R@chid]

Re : Calculer le nombre de fois où l'on retrouve un couple de cellule dans un tableau

Bonsoir @ tous,
Sans trier la 1ere colonne,
en F2 @ tirer vers le bas,

=NB.SI.ENS(A$2:A$11;GAUCHE(E2;TROUVE("-";E2)-2);DECALER(A$2:A$11;;EQUIV(STXT(E2;TROUVE("-";E2)+2;99);B$1:C$1;0));"X")

Amicalement