Calcul en fonction de mise en forme conditionnelle

[dl87671]

Bonjour,

Un petit coup de main, car les formules me posent problème.
Je joins un exemple.
Dans le fichier joint, composé de 2 colonnes, j'ai mis une forme conditionnelle pour faire apparaitre :
- en vert le nombre de date de la colonne CREATION avec un nombre de jours ouvrés par rapport à la date d'aujourd'hui <=5 et la colonne PAYE est vide
- en orange le nombre de date de la colonne CREATION avec un nombre de jours ouvrés par rapport à la date d'aujourd'hui compris en 5 et 10 et la colonne PAYE est vide
- en rouge le nombre de date de la colonne CREATION avec un nombre de jours ouvrés par rapport à la date d'aujourd'hui > 10 et la colonne PAYE est vide

Mon problème, je voudrais connaître en haut , le nombre de VERT, ORANGE et ROUGE.
Merci pour votre aide.
Didier.

 

[JHA]

Bonjour à tous,

En me servant de ta colonne "C"

JHA

 

[dl87671]

Ok merci beaucoup.
Mais sans la colonne C , y a t-il une solution?

 

[CISCO]

Bonsoir à tous, bonsoir JHA

Erreur

@ plus

 

[Chris401]

Bonjour

La formule de base serait :

=SOMMEPROD((NB.JOURS.OUVRES(A6:A23;AUJOURDHUI())<=5)*(B6:B23=""))

Cependant, la formule va d'abord calculer la partie NB.JOURS.OUVRES(A6:A23;AUJOURDHUI())<=5
en commençant par AUJOURDHUI() puis va calculer NB.JOURS.OUVRES(A6:A23;42733)
Les valeurs de la plage A6:A23 n'étant pas retournées le résultat donne #VALEUR<=5

Pour forcer le calcul de A6:A23 en premier, une astuce est de multiplier la plage par 1 (on peut lui ajouter 0 également)



Pour la couleur verte :

=SOMMEPROD((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())<=5)*(B6:B23=""))

Pour la couleur orange :

=SOMMEPROD((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>5)*(B6:B23=""))-SOMMEPROD((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>10)*(B6:B23=""))

Ou

=SOMMEPROD(((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>5)-(NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>10))*(B6:B23=""))

Ou

=SOMMEPROD((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>5)*(B6:B23=""))-B3

Pour la couleur rouge :

=SOMMEPROD((NB.JOURS.OUVRES(1*(A6:A23);AUJOURDHUI())>10)*(B6:B23=""))

 

[dl87671]

Merci à tous, j'avais essayé SOMMEPROD mais je me trouvais effectivement avec une erreur d'où ma solution de calculer le nombre de jours ouvrés.
Ce n'était pas sans compter avec les maîtres d'Excel.
Bonne fin d'année à tous et encore merci pour les astuces.

 

[CISCO]

Bonsoir à tous

Merci Chris401 pour cette astuce, le 1*...

@ plus