XL 2016 Calcul d'opération

[Claude5]

Bonjour à vous,

suite à une extraction de fichier, je souhaite obtenir le nombre d'opération par ligne. Voir la PJ

Pour les lignes 2 ou 3 par exemple, j'ai eu une formule à laquelle j'ai ajouté 1 qui me donne a priori un résultat correct. Par contre pour les lignes 19 et 20 je n'arrive pas du tout à trouver une formule qui prenne en compte le fait que la période du 27 mai au 26 juin pour la ligne 19 est effectuée les jours 6 et 7 c'est à dire samedi et dimanche. Donc au lieu de 10 je n'ai que 5. A noter pour la ligne 11 "coup de bol"

Merci de votre aide

 

[vgendron]

Hello

en fait. je ne comprend pas ce que tu souhaites calculer..

Ha.. je crois avoir deviné une partie..
Voir ici
https://www.excel-downloads.com/threads/nombre-de-dimanches-entre-2-dates.64994/

 

[JHA]

Bonjour à tous,

pour trouver le nombre de samedi et dimanche, peut être avec cette formule

=SOMMEPROD((JOURSEM(LIGNE(INDIRECT(D2&":"&E2));2)>5)*1)

JHA

 

[Claude5]

Bonjour à tous et merci.

Je me suis mal exprimé. Prenons cet exemple:
D XX 2126 27/5/17 25/6/17 _____67 FSC
dans cette ligne je cherche à savoir le nombre d'opération (1 par jour) entre le 27 mai et le 25 juin pour les 2 jours d'opération c'est à dire le samedi (6) et le dimanche (7)
Pour cet autre exemple ci dessous, le nombre d'opération entre le 29 juin et le 2 juillet pour le jeudi (4), le samedi (6) et le dimanche (7)
D XX 2126 29/6/17 2/7/17 ___4_67 FSC J 1 3

Merci/Claude

 

[JHA]

Bonjour à tous,

A essayer

=NB.JOURS.OUVRES.INTL(D2;E2;SI(ESTERREUR(STXT(F2;1;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;2;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;3;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;4;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;5;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;6;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;7;1)*1>0);1;0))

JHA

 

[JHA]

Bonjour à tous,

On peut aussi inclure les fériés

JHA

 

[Claude5]

Bonjour à tous,

merci de vos réponses. Dans mon exercice, par exemple, pour cette ligne D XX 2126 9/4/17 15/4/17 _____67 ,consistait à déterminer le nombre de jours 6 et 7 (samedi et dimanche) entre le 9 avril et et le 15 avril 2017

Et pour cette ligne D XX 2126 29/6/17 2/7/17 ___4_67 le nombre de jeudi, samedi et dimanche entre le 29 juin et le 2 juillet

J'ai appliqué cette formule et ça fonctionne.
=NB.JOURS.OUVRES.INTL(D2;E2;SI(ESTERREUR(STXT(F2;1;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;2;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;3;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;4;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;5;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;6;1)*1>0);1;0)&SI(ESTERREUR(STXT(F2;7;1)*1>0);1;0))

Merci encore/Claude

 

[JBOBO]

Bonjour à tous,

un peu tard, mais avec ce que j'ai compris.
=SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");1;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");2;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");3;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");4;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");5;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");6;1)))))*1);0)+SIERREUR(SOMMEPROD((JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(CNUM((STXT(SUBSTITUE(F2;"_";"");7;1)))))*1);0)

 

[Claude5]

Bonjour. Elle fonctionne aussi très bien.

Merci/Claude

 

[Claude5]

Bonjour. Elle fonctionne aussi très bien.

Merci/Claude

Rebonjour JBOBO, bonjour à tous,
toujours dans mon exercice en PJ, auriez-vous une formule qui me permette d'isoler par jour (mon encadré en rouge).

Merci encore/Claude

 

[JHA]

Bonjour à tous,

A essayer en "I2"

=SI(ESTNUM(CHERCHE(DROITE(I$1;1);$F2));NB(SI(JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)=(DROITE(I$1;1)*1);JOURSEM(LIGNE(INDIRECT($D2&":"&$E2));2)));"")

Formule matricielle

JHA

 

[Claude5]

[résolu] Bonjour JHA, vous êtes brillant!

Merci encore/Claude