Microsoft 365 Bug sur une macro

Sub SupprRecreeTS()
'
Dim P As Range, tablo
Dim NomTS As String

    Application.ScreenUpdating = False

    With Sheets("Suivi compte")
        NomTS = .ListObjects(1).Name    ' On sauvegarde le nom du TS
        Set P = .ListObjects(1).Range   ' Tableau structuré
        tablo = P                       ' Mémorise les valeurs
        P.Cells.Clear                   ' On efface toutes les cellules du TS
        P = tablo                       ' Restitue les valeurs
        With .ListObjects.Add(xlSrcRange, P, , xlYes)   ' Recrée le tableau structuré
            .Name = NomTS               ' On restaure le nom du TS
            .TableStyle = "TableStyleMedium8"
            If Not .DataBodyRange Is Nothing Then
                With .DataBodyRange
                    .Columns(1).Validation.Add xlValidateList, Formula1:="=INDIRECT(""_02.Symboles"")"
                    .Columns(2).NumberFormat = "0.00"
                     Union(.Columns(5), .Columns(6)).NumberFormat = "#,##0.00000"
                    .Columns(7).Validation.Add xlValidateList, Formula1:="A,V"
                    .Columns(10).FormulaR1C1 = "=IF([@[P/L]]="""","""",SUM([@[P/L]],OFFSET([@Marge],-1,1)))"
                    .Columns(9).NumberFormat = "#,##00.00"
                    Union(.Columns(8), .Columns(10)).NumberFormat = "#,##0.00;[Red]-#,##0.00"
                End With
            End If
            .Range.Columns(7).HorizontalAlignment = xlCenter
        End With
        P.Columns.AutoFit           ' Ajuste les largeurs des colonnes du TS
        With .UsedRange: End With   ' Actualise les barres de défilement
    End With

End Sub