XL 2019 Boucle / Userform / Planning d'absences

Private Sub CommandButton1_Click()
    Dim Du As Integer, Au As Integer
    Dim V As Variant
    '
    ' Si pas de choix en combobox sortir
    If ComboBox1.ListIndex = -1 Then Exit Sub
    '
    ' si textbox 1 ou textbox 2 ne sont pas numérique sortir
    If Not IsNumeric(TextBox1.Text) Then Exit Sub ' Peut-être prévenir l'utilisateur avant ?
    If Not IsNumeric(TextBox2.Text) Then Exit Sub ' Idem 
    '
    ' si rien dans textbox3 sortir
    If  trim(TextBox3.Text )= "" Then Exit Sub ' Idem

   'Conversion en entier des valeurs des textbox
    Du = CInt(TextBox1.Text)
    Au = CInt(TextBox2.Text)
    '
    ' si Au est inférieur à Du, intervertir les valeur
    If Au < Du Then
        V = Au
        Au = Du
        Du = V
    End If
    '
    ' Travailler sur la feuille BDD
    With Sheets("BDD").Range("Codes_Absences")
        '
        ' position du text de TextBox3 dans la colonne 1 de la plage Codes_Absences
        V = Application.Match(TextBox3.Text, .Columns(1), 0)
        '
        ' Si non trouvé avertir et sortir
        If IsError(V) Then
            MsgBox "Motif d' absence non trouvé!", vbExclamation, "Saisie absences"
            Exit Sub
        End If
        '
        ' Sinon récupérer le code dans la deuxième colonne, même ligne
        V = .Cells(V, 2)
    End With
    '
    ' Inscrire les données dans la ligne idoine
    With Sheets("Planning_ABS").Range("C4").CurrentRegion
        If Du = 0 Then Du = 1
        If Au = 0 Then Au = Application.Max(.Rows(1))
        .Cells(ComboBox1.ListIndex + 1, Du + 1).Resize(, Au - Du + 1) = V
    End With
End Sub