aide pour VBA excel

[FCAFE]

Bonjour à tous,

Je souhaiterai de l'aide concernant une macro, je suis une novice et j'ai besoin de votre aide

J'ai un fichier par lequel je souhaite exécuter plusieurs petites rectification par macro, je pense en bloucle mais je ne suis pas sur. Je vous joins un fichier.

Format lignes
police
changement sur nom
supression de colonnes

Pourriez vous m'aider

cordialement

 

[Theze]

Re : aide pour VBA excel

Bonjour,

Teste ceci :

Sub Modif()

    Dim Plage As Range
    Dim Cel As Range
    
    'plage définie en colonne A de la feuille active
    With ActiveSheet
    
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
        
    End With
    
    'boucle sur les cellules de la plage
    For Each Cel In Plage
        
        With Cel
            
            'utilise la fonction Trim() car présence d'espaces dans la cellule
            If UCase(Trim(.Value)) = "MONSIEUR" Then .Value = "Mr"
            If UCase(Trim(.Value)) = "MADAME" Then .Value = "Mme"
            If UCase(Trim(.Value)) = "SOCIETE" Then .Value = "sté"
            If UCase(Trim(.Value)) = "MONSIEUR OU MADAME" Then .Value = "Mr ou Mme"
            
        End With
               
    Next Cel
    
    Plage.Font.Name = "Calibri"
    Plage.Font.Size = 8
    Plage.RowHeight = 20
    
    Columns("B:C").EntireColumn.Delete

End Sub

Hervé.

 

[ROGER2327]

Re : aide pour VBA excel

Bonjour à tous

Comme on n'a pas de renseignement sur la plage à traiter, une procédure sommaire pour traiter la plage sélectionnée de la page active :

Sub Macro1() 'Opère sur la plage actuellement sélectionnée.
Dim i%, rpl()
    rpl = Array(Array("monsieur", "M."), Array("madame", "Mme"), Array("mademoiselle", "Mme"), _
        Array("societe", "Sté"), Array("société", "Sté")) 'À arranger à votre convenance.
    With Selection
        For i = 0 To UBound(rpl)
            .Replace What:=rpl(i)(0), Replacement:=rpl(i)(1), LookAt:=xlPart, _
                SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                ReplaceFormat:=False
        Next
        .RowHeight = 20
        With .Font
            .Name = "Calibri"
            .Size = 8
        End With
    End With
    Columns("B:C").Delete Shift:=xlToLeft
    Range("A1").Select 'facultatif
End Sub

ROGER2327
#5531

Hunyadi 29 Gueules 139 (hunyadi gras - Mouvement Perpétuel - Vacuation)
4 Ventôse An CCXX, 5,7734h - troêne
2012-W08-4T13:51:22Z

 

[FCAFE]

Re : aide pour VBA excel

bonsoir
merci de votre aide
bonne soirée

 

[FCAFE]

Re : aide pour VBA excel

Bonjour

Merci de votre aide

Bonne soirée

Cordialement