Aide pour boucle

[eduraiss]

Bonjour le forum

Voila j'ai une liste de nom, je voudrais les identifier a l'interieur d'un fichier par une couleur

Voici un exemple

Meci a vous

 

[R@chid]

Re : Aide pour boucle

Bonjour,
voir PJ avec une Mfc...
Amicalement

 

[eduraiss]

Re : Aide pour boucle

Bonjour et merci

Désolé mais la Mfc ne peut pas convenir les couleur ne doivent pas rester

Il faut passer par le vba

Meci quand même

 

[job75]

Re : Aide pour boucle

Bonjour eduraiss, salut R@chid,

Désolé mais la Mfc ne peut pas convenir les couleur ne doivent pas rester

Je ne comprends pas 😕

La MFC donnée par R@chid est de loin la meilleure solution.

Du VBA ne ferait que calculer la formule NB.SI...

S'il y a autre chose, il faut nous montrer le fichier réel.

A+

 

[eduraiss]

Re : Aide pour boucle

Bonjour,

le projet est trop lourd, mais une chose est clair la MFC ne peut pas fonctionner car je doit elever les couleurs

Petite explication dans le colonne O des noms qui changent trés souvent je veux juste lorsque je déclance la procedure que les noms soit identifier dans le tableau
Je sais boucler sur la premiere cellule de l

 

[eduraiss]

Re : Aide pour boucle

Ho pardon
je sais boucler sur la cellule 01 mais je voudrais continuer de boucler jusque la derniere cellule

merci

 

[laurent950]

Re : Aide pour boucle

Bonsoir eduraiss,

Peut être une solution

Sub proc_trouve_le_mot()

' Liste des nom dans un tableau "mémoire"
' correspond au cellule excel
' corespondance a avec la plage excel
' msgbox t(1,1)   1 = lignes est 1 Colonne (en mémoire machine)
' msgbox t(2,1)   2 = lignes est 1 Colonne (en mémoire machine) 
' msgbox t(3,1)   3 = lignes est 1 Colonne (en mémoire machine) 

Dim t()
t = Range("O1:O3")

Dim Maplage As Range
Dim UneCellule As Range

'MsgBox UneCellule
Set Maplage = Range("c4:k33")

Maplage.Interior.ColorIndex = xlNone

' Choix de vos couleur ici se sont des exemples comme : (ColorIndex = 5)
' a vous d'adapter

For Each UneCellule In Maplage
If UneCellule = t(1, 1) Then
UneCellule.Interior.ColorIndex = 5
ElseIf UneCellule = t(2, 1) Then
UneCellule.Interior.ColorIndex = 3
ElseIf UneCellule = t(3, 1) Then
UneCellule.Interior.ColorIndex = 6
End If
Next UneCellule

End Sub

laurent

 

[job75]

Re : Aide pour boucle

une chose est clair la MFC ne peut pas fonctionner car je doit elever les couleurs

Je suppose que vous voulez dire "enlever" ? Mais je ne comprends toujours pas.

Dans une MFC la couleur "s'enlève" toute seule quand la condition n'est plus vérifiée...

Expliquez nous clairement ce qui ne va pas avec la MFC et ce que vous voulez.

Perso je n'aime pas pondre du code VBA à l'aveuglette, surtout s'il ne doit servir à rien.

A+

 

[eduraiss]

Re : Aide pour boucle

re

concernant la MFC les couleurs restent et s’enlève toute seul , je suis d'accord, mais pour mon projet je dois faire des affichages de ses tableaux, et en aucun cas les couleurs ne doivent être visible
c'est une gestion d'équipe, les personnes ne comprendrais pas qu'il y ai de la couleur sur leurs noms
le code de laurent est presque ce qu'il me faut sauf que toutes les personnes de la liste doivent être identifier par la même couleur
je travail sur un tableaux de 300 lignes et la colonne "O" peut avoir plus de 100 noms
merci
en espérant avoir été plus clair

 

[job75]

Re : Aide pour boucle

c'est une gestion d'équipe, les personnes ne comprendrais pas qu'il y ai de la couleur sur leurs noms le code de laurent est presque ce qu'il me faut sauf que toutes les personnes de la liste doivent être identifier par la même couleur

Comprenne qui pourra, désolé d'enfoncer le clou 😕

A+

 

[job75]

Re : Aide pour boucle

Re,

Bon je crois avoir compris.

Vous voulez tout simplement colorer les cellules (et aussi effacer la couleur) quand vous voulez.

C'est si difficile à dire ???

Alors ces 2 macros à lancer par Ctrl+A et Ctrl+E :

Sub AfficherCouleur()
'se lance par touches Ctrl+A
Dim r As Range, plage As Range
Set r = [C4:K350] 'à adapter
Set plage = [O1:O150] 'à adapter
Application.ScreenUpdating = False
r.Interior.ColorIndex = xlNone 'RAZ par sécurité
For Each r In r
  If Application.CountIf(plage, r) Then _
    r.Interior.ColorIndex = 5
Next
End Sub

Sub EffacerCouleur()
'se lance par touches Ctrl+E
[C4:K350].Interior.ColorIndex = xlNone 'à adapter
End Sub

Fichier joint.

A+

 

[job75]

Re : Aide pour boucle

Re,

On peut aussi en VBA appliquer une MFC et l'effacer.

Sur une version française d'Excel :

Sub AfficherCouleur()
'se lance par touches Ctrl+A
Dim r As Range, plage As Range, F As String
Set r = [C4:K350] 'à adapter
Set plage = [O1:O150] 'à adapter
F = "=NB.SI(" & plage.Address & ";" & r(1).Address(0, 0) & ")"
EffacerCouleur 'RAZ
r.FormatConditions.Add xlExpression, Formula1:=F
r.FormatConditions(1).Interior.ColorIndex = 5
End Sub

Sub EffacerCouleur()
'se lance par touches Ctrl+E
[C4:K350].FormatConditions.Delete 'à adapter
End Sub

Plus besoin de boucle donc.

Fichier joint.

A+

 

[job75]

Re : Aide pour boucle

Bonjour eduraiss,

Si vous ne voulez pas qu'un utilisateur puisse afficher la couleur :

- mettre les noms en colonne A de Feuil2 qui est cachée xlVeryHidden

- mettre un mot de passe - eric - dans la 1ère macro et sur le VBAProject.

Fichier (2).

A+

 

[eduraiss]

Re : Aide pour boucle

bonjour le forum

Bonjour job75, désolé pour mon manque de précision hier, c'est ce qu'il me fallait mettre de la couleur dans les cellules, tes exemples sont parfait
le eric 10(1) me suffira

merci beaucoup