XL 2010 Vérifier contenu de même cellules sur plusieurs feuilles

Panda79360

XLDnaute Nouveau
Bonjour,

Je souhaiterais vérifier dans les feuilles 1.2 et 3 le contenu des cellules A,B et C.
Si elles sont toutes remplies, je voudrais renvoyer vers la feuil4.

Si une des cellules est vide, je souhaite afficher un msgbox indiquant qu'il faut remplir la cellule vide pour accéder à la feuil4.

Pouvez vous m'aider svp je tourne dans tous les sens mais je ne trouve pas


Merci beaucoup
 
Solution
Bonjour à tous,

Une autre version :
VB:
Sub Bouton1_Cliquer()
Dim xsh, xcell
   For Each xsh In Array("Feuil1", "Feuil2", "Feuil3")
      For Each xcell In Array("A2", "B2", "C2")
         If Trim(Sheets(xsh).Range(xcell)) = "" Then
            MsgBox "il y a au moins un critère vide." & vbLf & _
               "Cellule " & Range(xcell).Address(0, 0) & " sur " & xsh, vbCritical
            Application.Goto Sheets(xsh).Range(xcell)
            Exit Sub
         End If
   Next xcell, xsh
   Sheets("Feuil4").Activate
End Sub

Franc58

XLDnaute Occasionnel
Salut, voici une proposition:

VB:
Sub Bouton1_Cliquer()

    Dim ws As Worksheet
    Dim CelluleVide As Boolean
    CelluleVide = False

    ' Vérifier cellules A2, B2, C2 dans Feuil1, Feuil2, Feuil3
    For Each ws In ThisWorkbook.Sheets
        If ws.Name = "Feuil1" Or ws.Name = "Feuil2" Or ws.Name = "Feuil3" Then
            If IsEmpty(ws.Range("A2")) Or IsEmpty(ws.Range("B2")) Or IsEmpty(ws.Range("C2")) Then
                CelluleVide = True
                Exit For
            End If
        End If
    Next ws

    If CelluleVide Then
        MsgBox "Tous les critères ne sont pas remplis"
        Exit Sub
    End If

    ' Si pas de cellule vide, activation Feuil4
    ThisWorkbook.Sheets("Feuil4").Activate

End Sub
 

sousou

XLDnaute Barbatruc
re
De manière tres simpliste....
Public compt
Sub Bouton1_Cliquer()
compt = 0
For n = 1 To 3
Call controle(Sheets("feuil" & n))
Next
If compte = 9 Then
Sheets("feuil4").Activate
Else
MsgBox "vérifier les cellules manquantes"
End If

End Sub


Sub controle(feuil)
For n = 1 To 3
If feuil.Cells(2, n) <> "" Then compt = compt + 1
Next
End Sub
 

mapomme

XLDnaute Barbatruc
Supporter XLD
Bonjour à tous,

Une autre version :
VB:
Sub Bouton1_Cliquer()
Dim xsh, xcell
   For Each xsh In Array("Feuil1", "Feuil2", "Feuil3")
      For Each xcell In Array("A2", "B2", "C2")
         If Trim(Sheets(xsh).Range(xcell)) = "" Then
            MsgBox "il y a au moins un critère vide." & vbLf & _
               "Cellule " & Range(xcell).Address(0, 0) & " sur " & xsh, vbCritical
            Application.Goto Sheets(xsh).Range(xcell)
            Exit Sub
         End If
   Next xcell, xsh
   Sheets("Feuil4").Activate
End Sub
 

Pièces jointes

  • Panda79360- vérif présence critères - v1.xlsm
    22.6 KB · Affichages: 2
Dernière édition:

Phil69970

XLDnaute Barbatruc
Bonjour à tous

Et ma version ..... ultra simpliste ..... ;)

Code:
Sub Test()
Dim Verif$
Verif = Application.Evaluate("Counta(Feuil1:Feuil3!A2:C2)")
If Verif <> 9 Then
    MsgBox "Tous les critères ne sont pas remplis ", vbCritical, "PB !!!"
Else
   Sheets("Feuil4").Activate
End If
End Sub

Merci de ton retour
 

Pièces jointes

  • Verif si condition V1.xlsm
    21.6 KB · Affichages: 0

Discussions similaires

Statistiques des forums

Discussions
313 197
Messages
2 096 107
Membres
106 500
dernier inscrit
mmontagu