XL 2021 VBA - Comment savoir dans quel mode (vbModal / vbModeless) est affiché un UserForm

[Dudu2]

Bonjour,

A part tenter un ré-affichage vbModeless pas très satisfaisant, comment savoir le mode d'affichage d'un UserForm ?

 

[wDog66]

Bonjour,

A part tenter un ré-affichage vbModeless pas très satisfaisant, comment savoir le mode d'affichage d'un UserForm ?

Salut Dudu2

En VBA, il n'existe pas de fonction native pour le savoir, en revanche tu peux en créer une

 

[Dranreb]

Bonjour.
Personnellement je ne le précise jamais au Show car je considère que ce mode fait partie de la conception même de l'UserForm.
Je le définis donc toujours au niveau de sa propriété ShowModal.

 

[vgendron]

Hello

perso, je le vois tout de suite quand je ne peux pas naviguer dans Excel lorsque le userform est affiché.. et que du coup je me dis.. et m.... fait ch.. faut que je change le mode... :-D

 

[wDog66]

Re,

Sinon la possibilité d'une méthode générique

Dans un module standard

Option Explicit
Private formModes As Object ' Scripting.Dictionary

Public Sub InitFormModeTracking()
    If formModes Is Nothing Then Set formModes = CreateObject("Scripting.Dictionary")
End Sub

Public Sub ShowUserForm(UF As Object, Optional ByVal Mode As VbModal = vbModal)
    InitFormModeTracking
    formModes(UF.Name) = Mode
    UF.Show Mode
End Sub

Public Function GetFormMode(UF As Object) As VbModal
    InitFormModeTracking
    If formModes.exists(UF.Name) Then
        GetFormMode = formModes(UF.Name)
    Else
        ' Valeur par défaut si jamais non initialisée
        GetFormMode = vbModal
    End If
End Function

Et au lieu d'afficher ton USF

UserForm1.Show vbModeless

Tu fais

Call ShowUserForm(UserForm1, vbModeless)

Et pour connaitre le mode, dans ton USF

Dim mode As VbModal
mode = GetFormMode(UserForm1)
If mode = vbModal Then
    MsgBox "Modal"
Else
    MsgBox "Modeless"
End If

Voilà, tu ne trouveras pas mieux je pense

 

[Dudu2]

J'ai un assez grand nombre de UserForms dans une application complexe.
Le problème n'est pas lié à 1 UserForm particulier mais si je dois afficher un UserForm vbModeless dans un classeur alors qu'un UserForm vbModal est affiché dans un autre classeur je dois le savoir et l'identifier pour le fermer.

Alors je peux effectivement gérer un système comme l'indique @wDog66 avec pour chaque UserForm une variable associée indique comment il est affiché mais j'aimerais que ce soit direct.

 

[wDog66]

Re,

Entre "aimer avoir" et "avoir" il y a parfois un précipice infranchissable...

Je ne suis pas certain qu'avec des API Windows on puisse le faire.

Enfin bref, continuer dans votre recherche du saint graal...

 

[Dranreb]

Ça va rendre la main à la procédure qui en a effectué le Show, ça.

 

[Dudu2]

Oui, ça rend la main à la procédure ayant affiché le UserForm vbModal.
Il faut juste qu'elle ne fasse rien après le .Show vbModal ce qui est le cas si le UserForm est en mode affichage sans interaction.
Du moins si le code l'a prévu ainsi.

 

[Dranreb]

Dans ce cas ne vaudrait-il pas mieux que cet UserForm ait aussi sa propriété ShowModal à False ?

 

[Dudu2]

Dans ce cas il faut que je revoie les effets de bords.

 

[Rheeem]

Lorsque l'application entre en mode modal sa principale fenêtre devient inaccessible aux clavier et la souris
donc tester la fenêtre principale de l'application si son enabled est False == modal
Ca devrait fonctionner

IsWindowEnabled function (winuser.h) - Win32 apps

Determines whether the specified window is enabled for mouse and keyboard input.

learn.microsoft.com

 

[Dudu2]

OK @Rheeem je vais essayer ça.

 

[Dudu2]

C'est bien mais ça ne dit pas si un UserForm est modal ou pas d'autant que si les actions sont bloquées sur tous les classeurs, ce n'est pas le cas sur un nouveau classeur bien qu'Excel informe que l'opération d'ouverture d'un nouveau classeur n'est pas possible !

J'ai essayé les Styles et ExStyles du GetWindowLong() ou du GetWindowInfo() mais rien ne différencie le mode d'affichage.
Donc la seule méthode est celle du fichier du 1er post.

 

[patricktoulon]

re
Bonjour bonjour
comme ça vite fait un truc a l'arrache
on essaie de sélectionner une cellule (PAS PAR UN SELECT!!!!) mais par la simu de la souris
si la cellule change c'est qu'il est non modal

exemple un userform et un bouton

'patricktoulon
Private Type POINTAPI
    x As Long
    y As Long
End Type

Private Declare PtrSafe Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal dwData As Long, ByVal dwExtraInfo As Long)
Private Declare PtrSafe Function SetCursorPos Lib "user32" (ByVal x As Long, ByVal y As Long) As Long
Private Declare PtrSafe Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long

Private Const MOUSEEVENTF_LEFTDOWN As Long = &H2
Private Const MOUSEEVENTF_LEFTUP As Long = &H4

Private Sub CommandButton1_Click()
    Dim cell As Range, x, y, pt As POINTAPI
    Set cell = ActiveCell
    GetCursorPos pt
    'on prend les points de la cellule en dessous
    With ActiveWindow.ActivePane
        x = .PointsToScreenPixelsX(cell.Left)
        y = .PointsToScreenPixelsY(cell.Offset(2).Top - 2)
    End With
    'on y place le curseur
    SetCursorPos x, y
    ' on simule un clic gauche
    mouse_event MOUSEEVENTF_LEFTDOWN, 0, 0, 0, 0
    mouse_event MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
    DoEvents
    SetCursorPos pt.x, pt.y
    'si la cellule a changé au click souris simulé c'est que le userform est non modal sinon elle ne change pas donc modal
    MsgBox "Modal : " & CStr(cell.Address = ActiveCell.Address)
    cell.Select
End Sub