Utiliser difdate dans une MFC

[libellule85]

Bonsoir le forum,

Une question : comment utiliser difdate dans une MFC ?

J'ai une formule en D4 =DIFDATE(B4;AUJOURDHUI()) qui me donne comme résultat 30 ans 3 mois et 3 jours et je voudrais mettre une MFC sur ce résultat : si DIFDATE(B4;AUJOURDHUI()) est supérieur à 25 ans = remplir d'une couleur la cellule contenant ce résultat.

ci-joint fichier.

d'avance merci pour votre aide

 

[job75]

Re : Utiliser difdate dans une MFC

Bonjour libellulle85,

MFC sur toute la colonne D avec cette formule =--GAUCHE(D1;3)>25

A+

 

[gosselien]

Re : Utiliser difdate dans une MFC

Bonjour,

perso je connais celle-ci:

=DATEDIF(B4;AUJOURDHUI();"y") >25

P.

edit Hello à JOB75

 

[libellule85]

Re : Utiliser difdate dans une MFC

Bonsoir Job75, Gosselien,

Merci beaucoup pour vos réponses

 

[libellule85]

Re : Utiliser difdate dans une MFC

Re bonjour le forum,

@Job75 : par contre avec ta formule =--GAUCHE(D1;3)>25 si je fais >30 cela ne sélectionne pas le 30 ans 3 mois et 4 jours !!

 

[job75]

Re : Utiliser difdate dans une MFC

Bonjour libellule85,

Formule en D1 pour la MFC sur toute la colonne D :

=NB(LN(--GAUCHE(D1;3)>30);CHERCHE("30 an*mois";D1);CHERCHE("30 an*jour";D1))

A+

 

[job75]

Re : Utiliser difdate dans une MFC

Re,

Bien sûr si la valeur limite (30) est paramétrée, par exemple en A1, on utilisera la formule :

=NB(LN(--GAUCHE(D1;3)>A$1);CHERCHE(A$1&" an*mois";D1);CHERCHE(A$1&" an*jour";D1))

A+

 

[libellule85]

Re : Utiliser difdate dans une MFC

Re,

merci beaucoup pour ton aide

 

[job75]

Re : Utiliser difdate dans une MFC

Re,

On aura bien vu qu'il y a un espace devant les textes en D4: D7.

Et donc que les formules que j'ai données fonctionnent avec une limite comprise entre 1 et 99.

Cette formule fonctionne avec ou sans espace et quelle que soit la limite :

=NB(LN(--GAUCHE(SUPPRESPACE(D1);TROUVE(" ";SUPPRESPACE(D1)))>A$1);CHERCHE(A$1&" an*mois";D1);CHERCHE(A$1&" an*jour";D1))

Fichier joint.

A+

 

[libellule85]

Re : Utiliser difdate dans une MFC

Re,

à nouveau un très grand merci pour ta réponse, c'est exactement ce que je recherchais.

 

[job75]

Re : Utiliser difdate dans une MFC

Bonjour libellule85, le forum,

La formule précédente "pèse" 95 octets en mémoire.

Celle-ci est nettement plus légère (67 octets) :

=(--GAUCHE(SUPPRESPACE(D1);TROUVE(" ";SUPPRESPACE(D1)))>A$1)+ESTNUM(CHERCHE(A$1&" an??";SUPPRESPACE(D1)))

Fichier (2).

Bonne journée.

 

[job75]

Re : Utiliser difdate dans une MFC

Re,

Un complément utile s'il n'y a pas d'année dans le texte :

=(--GAUCHE(SUPPRESPACE(D1);CHERCHE(" "&REPT("a";SIGNE(A$1));SUPPRESPACE(D1)))>A$1)+ESTNUM(CHERCHE(A$1&" an??";SUPPRESPACE(D1)))

On peut tester avec la limite 0 en A1 (ou A1 vide).

La formule "pèse" 83 octets.

Fichier (3).

A+

 

[libellule85]

Re : Utiliser difdate dans une MFC

Bonjour Job75,

Un très très grand merci pour ces deux améliorations. C'est vraiment sympa de ta part.