Trouver le 6e mot/chiffre d'une phrase

[Catoux]

Bonjour,

je cherche une formule qui va trouver ce qui apparait après le 5e espace!

Ça peut être les 4 caractères après le 5e espace.

Dans ma cellule A1 j'ai ce texte-ci: 26 74,3 78,8 78,8 7 20,0 21,2 100,0 33 94,3 100,0 2 5,7 35 100,0

Je veux que excel me trouve le chiffre 20,0 qui est situé après le 5e espace.
Il est possible que les chiffres changent donc c'est pour ça que je dois me fier aux espaces et non au nombre de caractères.

 

[JHA]

Bonjour à tous,

A essayer

=STXT(A2;CHERCHE("ù";SUBSTITUE(A2;" ";"ù";5))+1;4)

JHA

 

[Catoux]

Tellememt contente ça fonctionne merci merci merciii

 

[JHA]

Bonjour à tous,

Si tu as plus ou moins de 4 caractères entre les espaces.

=STXT(A2;CHERCHE("ù";SUBSTITUE(SUBSTITUE(A2;" ";"ù";5);" ";"Ω";5))+1;(CHERCHE("Ω";SUBSTITUE(SUBSTITUE(A2;" ";"ù";5);" ";"Ω";5)))-(CHERCHE("ù";SUBSTITUE(SUBSTITUE(A2;" ";"ù";5);" ";"Ω";5))+1))

JHA

 

[job75]

Bonsoir Catoux, JHA,

Fichier joint avec cette fonction VBA :

Function Trouve6(t$)
Trouve6 = ""
If UBound(Split(t)) > 4 Then Trouve6 = Split(t)(5)
If IsNumeric(Trouve6) Then Trouve6 = CDbl(Trouve6)
End Function

Le code doit être impérativement dans un module standard.

A+

 

[mapomme]

Bonsoir,
Une autre formule :

=SIERREUR(1*SUPPRESPACE(DROITE(SUBSTITUE(GAUCHE(A1 & REPT(" ";6);CHERCHE("x";SUBSTITUE(A1 & REPT(" ";6);" ";"x";6))-1);" ";REPT(" ";255));255));"")

La formule précédente recherche un nombre. Si vous voulez un mot, supprimez 1* dans la formule.

 

[Catoux]

Merci pour vos excellentes réponses! Je ne connais pas du tout le VBA

Je cherche une façon de remplacer A6 de cette formule pour que ça fasse référence au mot Trouble mémoire, car cette valeur peut ne pas se retrouver à la même position d'un excel à l'autre.. Dans la première partie de cette formule j'ai insérer (DECALER(INDEX(A1:A21;EQUIV("Trouble mémoire";A1:A21;0);1);5;0) comme formule substitue à A6 mais ça ne fonctionne pas pour le A6 après SUBSTITUE. Je n'y arrive pas malgré plusieurs essaies différents.

FORMULE COMPLÈTE:
=STXT(DECALER(INDEX(A1:A21;EQUIV("Trouble mémoire";A1:A21;0);1);5;0);CHERCHE("ù";SUBSTITUE(A6;" ";"ù";5))+1;4)

 

[Catoux]

Bonsoir,
Une autre formule :

=SIERREUR(1*SUPPRESPACE(DROITE(SUBSTITUE(GAUCHE(A1 & REPT(" ";6);CHERCHE("x";SUBSTITUE(A1 & REPT(" ";6);" ";"x";6))-1);" ";REPT(" ";255));255));"")

La formule précédente recherche un nombre. Si vous voulez un mot, supprimez 1* dans la formule.

C'est PRESQUE parfait!!!! Il renvoit seulement 1 chiffre d'avance donc ça renvoit au chiffre 7 au lieu de 20.0 dans mon fichier lorsque je copie colle la formule. Mais je vais vérifier avec votre démonstration excel! Merci !!

 

[JHA]

Bonjour à tous,

A essayer

=STXT(DECALER(INDEX(A1:A21;EQUIV("Trouble mémoire";A1:A21;0);1);5;0);CHERCHE("ù";SUBSTITUE(DECALER(INDEX(A1:A21;EQUIV("Trouble mémoire";A1:A21;0);1);5;0);" ";"ù";5))+1;4)

JHA