Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

[chemist]

Bonjour

Je ne sais pas trop comment l'expliquer donc voici un petit fichier

Dans mon exemple j'aimerais que la valeur de la cellule D2 soit "copié" dans la cellule D12. Lorsqu'il y aura une valeur dans la cellule E3 j'aimerais alors que ça soit E2 qui soit "copié" dans D12 et ainsi de suite.

Merci

Edit : sans macro svp car ça doit être automatique

 

[KenDev]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Bonjour Chemist,

=NB(3:3)

devrait faire l'affaire en l'état. Si jamais la numérotation de la ligne 2 devient différente de 1, 2, 3 etc.. mais reste numérique

=INDIRECT(ADRESSE(2;NB(3:3)+1))

Cordialement

KD

 

[chemist]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

merci j'avais justement trouvé nbval(3:3)

mais je vais regarder la fonction indirect, il doit aussi avoir la fonction décalé qui fonctionne

 

[chemist]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

=NB(3:3)

devrait faire l'affaire en l'état. Si jamais la numérotation de la ligne 2 devient différente de 1, 2, 3 etc.. mais reste numérique

=INDIRECT(ADRESSE(2;NB(3:3)+1))

Cordialement

KD

Pourquoi le +1 dans la formule indirect

 

[KenDev]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Re,

Parceque NB(3:3) compte les nombres de la ligne 3. La colonne 1 ayant nom1 comme valeur à la ligne 3 on ajoute 1 puisqu'elle ne sera pas comptée, le but dans cet argument de ADRESSE étant d'avoir un n° de colonne. cordialement

KD

 

[hoerwind]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Bonjour, salut KenDev,

Si j'ai compris la question il y a aussi :

=DECALER($A8;;NB.SI($B8:$BQ8;">0"))

 

[Monique]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Bonjour,

Encore avec Decaler()
=DECALER(A2;;NB(3:3))

ou bien
=DECALER(A2;0;NB(3:3))

 

[chemist]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Bonjour

KenDev, effectivement la numérotation augmente toujours de 1 mais ne commence pas nécessairement par 1 donc j'oublie =NB(3:3)

KenDEv et Monique vos formules fonctionnent bien sauf dans le cas ou une colonne reste vide. C'est-a-dire que si par exemple il n'y a aucune valeur pour la colonne 7 et ensuite je continu a entrer des valeurs dans les colonnes suivantes il ne trouve plus la dernière colonne remplie.

hoerwind la formule retourne la valeur de la ligne 8 et j'ai modifié pour obtenir la ligne 2 également car j'ai besoin des 2. Cependant si une colonne reste vide ou avec une valeur de 0 ca ne fonctionne plus.

 

[hoerwind]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

Bonjour,

Je commence petit à petit à comprendre ton problème.

Essaie ceci en D12 :
=DECALER(A2;;EQUIV(RECHERCHE(9^9;B3:BQ3);B3:BQ3))

En D13 remplace VRAI par FAUX (ou 0)

 

[KenDev]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

KenDEv et Monique vos formules fonctionnent bien sauf dans le cas ou une colonne reste vide. C'est-a-dire que si par exemple il n'y a aucune valeur pour la colonne 7 et ensuite je continu a entrer des valeurs dans les colonnes suivantes il ne trouve plus la dernière colonne remplie.

Bonjour Chemist, Monique, Hoerwind,

Pour rester dans la même logique, en matriciel :

=INDIRECT(ADRESSE(2;MAX((3:3<>"")*COLONNE(1:16384))))

Remplacer 16384 par 256 pour Excel <=2003.

Cordialement

KD

 

[chemist]

Re : Trouver la dernière cellulle d'une ligne où il y a une valeur en dessous

hoerwind et Kendev merci beaucoup ça fonctionne parfaitement!

Je test encore un peu pour valider, mais tout semble parfait

Il me reste également a mieux comprendre les 2 formules....