tri et classement avec conditions compliquées

[alf43]

bonjour, je mets en place un prog d'engagement pour compet judo mais suis incapable de créer en vba les codes pour résoudre la mise en poule de mes inscrits en fonction de leur poids.
je joins un fichier excel avec une base de poids et qq infos.
merci de votre aide. attention c'est assez difficile à faire.

 

[Kobaya]

Re : tri et classement avec conditions compliquées

salut alf43,

Je pense que cette macro répond à ton besoin :

Sub PoulesAuto()
    Dim intNumPoule As Integer
    Dim intIndex    As Integer
    Dim dblPoids    As Double
    Dim lngLigne    As Long
    
    ' lancer la macro après avoir trié les poids par ordre croissant
    intNumPoule = 1                         ' numéro de poule
    lngLigne = 3                            ' ligne traitée
    dblPoids = Cells(lngLigne, 1).Value     ' mémoriser le plus petit poids de la poule
    Cells(lngLigne, 2).Value = intNumPoule
    intIndex = 1                            ' nombre de personnes dans une poule
    lngLigne = lngLigne + 1
    Do Until Cells(lngLigne, 1).Value = ""
        If Cells(lngLigne, 1).Value > dblPoids * 1.1 Then
            ' poule suivante
            dblPoids = Cells(lngLigne, 1).Value
            intNumPoule = intNumPoule + 1
            intIndex = 1
        Else
            intIndex = intIndex + 1
        End If
        If intIndex > 4 Then
            intIndex = 1
            intNumPoule = intNumPoule + 1
            dblPoids = Cells(lngLigne, 1).Value
        End If
        
        ' inscrire le numéro de poule
        Cells(lngLigne, 2).Value = intNumPoule
        lngLigne = lngLigne + 1
    Loop
End Sub

 

[alf43]

Re : tri et classement avec conditions compliquées

salut kobaya,
je viens de torturer ton code et il est sans faute ....génial !!
maintenant je lui ajouterai d'insérer une ou plusieurs lignes vides pour avoir des groupes de 4 et pouvoir lancer mon autre macro de publipostage sur word.
comme tu vois j'ai encore du taf .. loll
merci de ton aide et au plaisir de t'avoir à+
🙂😀