Transformer Fichier excel en pdf

[bryc]

voila mon probleme, j'ai adobe acrobat 8 et je voudrais creer une macro qui m'imprime toute mes feuille excel en format pdf, quand j'ai creer une macro qui va page par page et imprime le contenu de la feuille avec l'imprimante d'adobe, a la fin j'obtient autant de fichier pdf que de feuille excel, et en plus elle ne sont pas complete alors comment faire

 

[JNP]

Re : Transformer Fichier excel en pdf

Bonjour le forum ,
Grace à Skoobi, Bhbh et BrunoM45, voici la solution qui devrait te convenir :

Dim Feuille As Worksheet
For Each Feuille In ActiveWorkbook.Sheets
Select Case Feuille.Name
     Case "Feuille que je ne veux pas imprimer"
     Case Else
         Feuille.Select Replace:=False
End Select
Next Feuille
ActiveWorkbook.PrintOut

Bon WE

 

[kiki29]

Re : Transformer Fichier excel en pdf

Jour Bon

'   sous VBE Menu Outils | Références
'   Cocher Acrobat Distiller

' Impression des Feuilles dans un seul Pdf 
Sub Tst2()
Dim sNomFichierPS As String
Dim sNomFichierPDF As String
Dim sNomFichierLog As String
Dim PDFDist As PdfDistiller

    sNomFichierPS = ThisWorkbook.Path & "\Essai_Distiller2.ps"
    sNomFichierPDF = ThisWorkbook.Path & "\Essai_Distiller2.pdf"
    sNomFichierLog = ThisWorkbook.Path & "\Essai_Distiller2.log"
    
    Sheets(Array("Feuil1", "Feuil2", "Feuil3", "Feuil4")).PrintOut copies:=1, Preview:=False, _
                                               ActivePrinter:="Acrobat Distiller", PrintToFile:=True, _
                                               PrToFileName:=sNomFichierPS

    Set PDFDist = New PdfDistiller
    PDFDist.FileToPDF sNomFichierPS, sNomFichierPDF, ""
    Set PDFDist = Nothing

    Kill sNomFichierPS
    Kill sNomFichierLog
End Sub

 

[kiki29]

Re : Transformer Fichier excel en pdf

On peut également utiliser ceci ,si l'on a une imprimante Acrobat installée mais qu'elle n'est pas celle par défaut

Private Function Imprimante_AdobePDF() As String
Dim i As Integer
Dim NomPortReseau As String
    ' 11 imprimantes réseau
    For i = 0 To 10
        If i < 10 Then
            NomPortReseau = "Adobe PDF sur Ne0" & i & ":"
        Else
            NomPortReseau = "Adobe PDF sur Ne" & i & ":"
        End If
        On Error Resume Next
        Application.ActivePrinter = NomPortReseau
        If ActivePrinter = NomPortReseau Then
            Exit For
        End If
    Next i
    Imprimante_AdobePDF = NomPortReseau
End Function

 

[kiki29]

Re : Transformer Fichier excel en pdf

re, le fichier Excel modifé le 13 Jun 2008