Transformer date en semaine/année

[flam72]

Bonjour,

Sur le forum, j'ai trouvé comment transformer une date en semaine mais aucun avec l'année en complément

je souhaite transformer le 25/11/2016 en S48/2016

Quel est le complément de formule à =NO.SEMAINE(C2;2) ?

Merci,

OZ

 

[chris]

Bonjour

en france une semaine commence un lundi et termine un dimanche et décalée d'un jour en moins pour les autres de l'autre coté de l'atlantique

Pas très clair ! La semaine américaine va effectivement du dimanche au samedi mais mais là il s'agit des numéros de semaines et de la différence entre la norme US et la norme ISO

J'ai réussi à le faire avec des SI imbriqués

Un seul SI suffit
="s"&NO.SEMAINE(date;21)&"/"&ANNEE(date)-SI(MOIS(date)<12;2001;2000)
ou plus court
="s"&NO.SEMAINE(date;21)&"/"&ANNEE(date)-(MOIS(date)<12)-2000

 

[Patrick A]

Bonjour

Pas très clair ! La semaine américaine va effectivement du dimanche au samedi mais mais là il s'agit des numéros de semaines et de la différence entre la norme US et la norme ISO


Un seul SI suffit
="s"&NO.SEMAINE(date;21)&"/"&ANNEE(date)-SI(MOIS(date)<12;2001;2000)
ou plus court
="s"&NO.SEMAINE(date;21)&"/"&ANNEE(date)-(MOIS(date)<12)-2000

Merci
Avec ces dernières formules, j'ai ce qu'il me faut.
Pour moi, c'est clos.

Et merci à tous pour vos idées, j'ai encore appris quelques trucs

 

[chris]

RE

En fait cela ne marche pas correctement car si on table sur le mois complet cela ne colle pas
Ceci semble OK

="s"&NO.SEMAINE(E1;21)&"/"&ANNEE(E1)-(E1<DATE(ANNEE(E1);1;1)-JOURSEM(DATE(ANNEE(E1);1;1);2)+8)-2000

Je cherche plus court
sur 365
=LET(Un;DATE(ANNEE(E1);1;1);"s"&NO.SEMAINE(E1;21)&"/"&ANNEE(E1)-(E1<Un-JOURSEM(Un;2)+8)-2000)

 

[JHA]

Bonjour à tous,

Un essai avec la date en "B1"

=SI(NO.SEMAINE.ISO(B1)<52;"S"&NO.SEMAINE.ISO(B1)&"/"&ANNEE(B1);"S"&NO.SEMAINE.ISO(B1)&"/"&ANNEE((B1+(1-JOURSEM(B1;2)))))

JHA

 

[eriiic]

Bonjour à tous,

ce que j'utilise :

=ANNEE(A2)+ET(MOIS(A2)=12;NO.SEMAINE.ISO(A2)=1)-ET(MOIS(A2)=1;NO.SEMAINE.ISO(A2)>51)&"-"&TEXTE(NO.SEMAINE.ISO(A2);"00")

je préfère l'année devant pour les tris
eric

 

[Vilou]

Bonjour,

et si je souhaite obtenir la date avec les 2 derniers digits de l'année. S14/22 au lieu de S14/2022 peut on l'obtenir à l'aide d'une formule?

 

[Efgé]

Bonjour
en A1 une date
En A2

="S"&NO.SEMAINE.ISO(A1)&"/"&TEXTE(A1;"aa")

Cordialement

 

[Modeste geedee]

Bonjour,

Sur le forum, j'ai trouvé comment transformer une date en semaine mais aucun avec l'année en complémen

L'année c'est l'annee du jeudi de la semaine concernée

 

[Efgé]

Bonjour,

et si je souhaite obtenir la date avec les 2 derniers digits de l'année. S14/22 au lieu de S14/2022 peut on l'obtenir à l'aide d'une formule?

L'année c'est l'annee du jeudi de la semaine concernée

Heu.... Comprend pas...

 

[eriiic]

Bonjour à tous,

="S"&TEXTE(NO.SEMAINE.ISO(A2);"00")&"/"&ANNEE(A2)+ET(MOIS(A2)=12;NO.SEMAINE.ISO(A2)=1)-ET(MOIS(A2)=1;NO.SEMAINE.ISO(A2)>51)-2000

mais avec l'année devant, tu pourrais trier correctement.
eric

 

[Modeste geedee]

Heu.... Comprend pas...

="S"&no.semaine(a1;21) & texte(A1-joursem(a1;3)+3;"\/aa")