XL 2010 Transformer chiffre en date

Dranreb

XLDnaute Barbatruc

• 21 Juillet 2017

• #2

Bonjour.
Essayez :

Code:

=DATE(MOD(A1;10000);MOD(ENT(A1/10000);100);ENT(A1/1000000))

 

Vote positif 0 Vote négatif

M12

XLDnaute Accro

• 21 Juillet 2017

• #3

Bonjour

Teste avec cette formule

Code:

=SI(NBCAR(A1)=8;DATE(STXT(A1;5;4);STXT(A1;3;2);STXT(A1;1;2));DATE(STXT(A1;4;4);STXT(A1;2;2);STXT(A1;1;1)))

 

Vote positif 0 Vote négatif

Chris24

XLDnaute Impliqué

• 21 Juillet 2017

• #4

Bonjour à tous

Code:

=TEXTE(A1;"00\/00\/0000")*1
ou bien
=DATEVAL(GAUCHE(A1;2)&"/"&STXT(A1;3;2)&"/"&DROITE(A1;4))
si pas de calcul avec les dates
=TEXTE(A1;"##\/##\/####")

 

Vote positif 0 Vote négatif

piga25

XLDnaute Barbatruc

• 21 Juillet 2017

• #5

Bonjour;
Fonctionne avec les dates suivantes : 01012017 - 1012017 - 010117 - 10117

Code:

=DATE(DROITE(A1;2);SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);DROITE(GAUCHE(A1;3);2);DROITE(GAUCHE(A1;4);2));SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);GAUCHE(A1);GAUCHE(A1;2)))

 

Vote positif 0 Vote négatif

mdo100

XLDnaute Occasionnel

• 21 Juillet 2017

• #6

Bonjour à toutes et tous,

J'ai une belle collection pour convertir un nombre en date, toutefois, je n'avais pas celle de piga25, qu'on peut améliorer un soupçon, si on ne veux pas rester dans le siècle dernier

Code:

=DATE(DROITE(A1;2)+100;SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);DROITE(GAUCHE(A1;3);2);DROITE(GAUCHE(A1;4);2));SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);GAUCHE(A1);GAUCHE(A1;2)))

Cordialement.

 

Vote positif 0 Vote négatif

M

merabet amine

XLDnaute Nouveau

• 31 Décembre 2018

• #7

bonjour
moi jais le numero 5102018 j'arrive pas a le convertire en format date svp une solution

 

Vote positif 0 Vote négatif

Chris24

XLDnaute Impliqué

• 31 Décembre 2018

• #8

Bonjour

Et pourtant les différentes solutions proposées te donnent bien une date

Cdt

 

Pièces jointes

• Date.xlsx

  9.6 KB · Affichages: 37

Vote positif 0 Vote négatif