[résolu] Comment comparer une date avec une heure fixe ?

[Bboon]

Bonjour,

J'ai un tableau relativement compliqué dans lequel j'ai 3 lignes très simples :
A = date
B = heure de relevé (au format jj/mm/aa hh:mm)
C = respect du protocole (au format standard avec une mise en forme conditionnelle)

la plage horaire de tolérance du relevé est 22h30 / 23h30 (j'aimerais que cela n'apparaisse pas dans le tableau pour ne pas l'alourdir)

Comment faire pour avoir une formule qui correspond à :
si B1<22h30 alors C1=oui
si 22h30<=B1<23h30 alors C1=+ / -
si 23h30<=B1 alors C1=non

La formule serait du style (en C1) : si(B1<22:30;"oui";si(et(22:30<=B1;B1<23:30);"+ / -;"non")))

Un exemple de données :

1 2 3
A 15/04/15 16/04 17/04
B 15/04/15 21:55 16/04/15 22:45 18/04/15 00:25
C oui + / - non

Je joins un fichier au besoin (la mise en forme conditionnelle ne fonctionne pas pour "+ / -" si quelqu'un a une idée je suis prenante 🙂 )

Je sais travailler avec des cellules qui contiennent soit des dates soit des heures mais là je suis bloquée .

Merci beaucoup pour votre aide.

 

[Victor21]

Re : Comment comparer une date avec une heure fixe ?

Bonjour Bbon.

Votre fichier ne correspond pas à l'énoncé.
Pour répondre à l'énoncé, essayez :

=SI(MOD(B1;1)<22.5/24;"Oui";SI(MOD(B1;1)<=23.5/24;"+ / -";"Non"))

B1 avec une date+ heure, MOD(B;1) renvoie l'heure seule et ENT(B1) renvoie la date seule.

 

[Dranreb]

Re : Comment comparer une date avec une heure fixe ?

Bonjour.

Dans l'exemple vous espérez "non" pour 00:25.
Alors à partir de quelle heure ça devient "oui" ?
En attendant la formule qui renvoie "non" seulement entre 23:30 et 23:59 est, en colonne B :

=CHOISIR(MAX(MOD(B$4;1)*24-20,5;1);"oui";"+ / -";"non")

Edit: Bonjour Victor21

 

[Bboon]

Re : Comment comparer une date avec une heure fixe ?

Bonjour Victor21 et Danreb,

Merci pour vos réponses aussi rapides.
Effectivement mon fichier des erreurs, j'en suis désolée.

J'aimerais que "oui" s'affiche si le relevé est effectué entre 14h et 22h30 le jour même, "+ / -" entre 22h30 et 23h30 le jour même et "non" entre 23h30 le jour même et 8h le lendemain.

Cordialement

 

[Victor21]

Re : Comment comparer une date avec une heure fixe ?

Re,

Essayez :

=SI(ET(MOD(B2;1)<=22.5/24;MOD(B2;1)>=14/24;ENT(B1)=ENT(B2));"Oui";SI(ET(MOD(B2;1)<23.5/24;MOD(B2;1)>22.5/24;ENT(B1)=ENT(B2));"+ / -";"Non"))

Le cas entre 8h et 14h n'est pas traité. Il conviendra d'ajouter une condition s'il peut se produire.

Edit : Je m'aperçois que je n'ai pas encore salué Dranreb. Une regrettable omission maintenant réparée 😉
PS : mon séparateur décimal est le point. Remplacez-le par la virgule dans la formule le cas échéant.

 

[Dranreb]

Re : Comment comparer une date avec une heure fixe ?

=CHOISIR(EQUIV(MOD(B$2;1)*24;{0;8;14;22,5;23,5});"non";"?";"oui";"+ / -";"non")

Remarque: Sous réserve d'un réglage du texte à rendre aux bornes elles mêmes.

Edit: Ou alors s'il faut tenir compte du délai entre les heures de la ligne 2 et celles de la ligne 1 (ce sont des dates seules, elles reviennent donc à des dates+0h), ce serait peut être plutôt, en B3 :

=CHOISIR(EQUIV((B$2-B$1)*24;{0;14;22,5;23,5;32});"?";"oui";"+ / -";"non";"?")

Edit: Bonsoir à toi aussi Victor21

 

[Bboon]

Re : Comment comparer une date avec une heure fixe ?

Bonjour Victor21 et Danreb,

Je suis désolée de vous répondre aussi tardivement. Je vous remercie sincèrement pour vous êtes penchés sur mon problème. Les formules fonctionnent hyper bien.

Effectivement, la première ligne du tableau indique simplement la date du jour et n'a qu'une fonction d'information.
La plage horaire 8h-14h ne doit pas être traitée sinon on risque d'avoir des ennuis avec la hiérarchie 🙄

Passez un très bon week-end.

Cordialement,