XL 2010 Transformer chiffre en date

[Fibule86]

Bonjour,

Je souhaite saisir des dates de naissance plus rapidement en saisissant 25041976 et ainsi transformer ma cellule en 25/04/1976. J'ai donc adapter une formule trouvé sur un autre forum

=DATE(DROITE(A1;4);STXT(A1;3;2);GAUCHE(A1;2))

Cela fonctionne pour la date de mon exemple mais je coince sur des dates commençant par 0 : par exemple 03072017 donne 30/12/2022.

Une idée car là je sèche.

Merci pour votre aide.

Je précise que j'ai posté ce message également dans le forum Developpez.net, dans la discussion (résolue depuis 2010) dans laquelle j'ai trouvé la formule.

 

[Dranreb]

Bonjour.
Essayez :

=DATE(MOD(A1;10000);MOD(ENT(A1/10000);100);ENT(A1/1000000))

 

[M12]

Bonjour

Teste avec cette formule

=SI(NBCAR(A1)=8;DATE(STXT(A1;5;4);STXT(A1;3;2);STXT(A1;1;2));DATE(STXT(A1;4;4);STXT(A1;2;2);STXT(A1;1;1)))

 

[Chris24]

Bonjour à tous

=TEXTE(A1;"00\/00\/0000")*1
ou bien
=DATEVAL(GAUCHE(A1;2)&"/"&STXT(A1;3;2)&"/"&DROITE(A1;4))
si pas de calcul avec les dates
=TEXTE(A1;"##\/##\/####")

 

[piga25]

Bonjour;
Fonctionne avec les dates suivantes : 01012017 - 1012017 - 010117 - 10117

=DATE(DROITE(A1;2);SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);DROITE(GAUCHE(A1;3);2);DROITE(GAUCHE(A1;4);2));SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);GAUCHE(A1);GAUCHE(A1;2)))

 

[mdo100]

Bonjour à toutes et tous,

J'ai une belle collection pour convertir un nombre en date, toutefois, je n'avais pas celle de piga25, qu'on peut améliorer un soupçon, si on ne veux pas rester dans le siècle dernier 😉

=DATE(DROITE(A1;2)+100;SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);DROITE(GAUCHE(A1;3);2);DROITE(GAUCHE(A1;4);2));SI(OU(NBCAR(A1)=7;NBCAR(A1)=5);GAUCHE(A1);GAUCHE(A1;2)))

Cordialement.

 

[merabet amine]

bonjour
moi jais le numero 5102018 j'arrive pas a le convertire en format date svp une solution

 

[Chris24]

Bonjour

Et pourtant les différentes solutions proposées te donnent bien une date

Cdt