Tableau d'unités et de tranches

[JJ1]

Bonjour à tous,
J'ai fait un tableau où je recenserai les unités et les tranches d'une série de 5 nombres.
Je voudrais remplir ce tableau.
Je joins un exemple du résultat à obtenir.
Je vous remercie
Bon AM

 

[Tibo]

Re : Tableau d'unités et de tranches

Bonjour,

Essaye en O16 :

=SOMMEPROD((MOD($A$3:$E$3;10)=O15)*1)

en O30 :

=SOMMEPROD((ENT($A$3:$E$3/10)=(COLONNES($O$29:O29)-1))*1)

Formules à recopier vers la droite


@+

 

[JeanMarie]

Re : Tableau d'unités et de tranches

Bonjour JJ1, Tibo

Une variante en matricielle, plage O16:X16 à sélectionner avec de saisir la formule

=TRANSPOSE(FREQUENCE(MOD(A3:E3;10);O15:X15))

pour la tranches, plage O30:S30

=TRANSPOSE(FREQUENCE(ENT(A3:E3/10);O15:S15))

EDITO : il ne faut pas de cellules vides dans la plages du 1er argument, ces cellules seront considérées comme ayant la valeur 0, elles fausseront donc le calcul.

@+Jean-Marie

 

[JJ1]

Re : Tableau d'unités et de tranches

Bonjour Tibo, Jean Marie, Le forum
Merci à vous deux pour ces formules condensées qui remplacent dans mon fichier toutes les conditions SI existantes (elles étaient nombreuses!).

à Tibo:
J'ai pas encore pu vérifier l'exactitude du résultat de ta formule (et quelle formule...bravo!) concernant l'écart moyen. C'est vrai que ce n'est pas du simple!
Il me semble que, dans ce même registre et si mes souvenirs sont bons(?), _Ti avait fait une formule avec une fonction produitmat, je vais chercher le lien (si adéquat) et je le dépose.
Je te tiens au courant.
Tu me parlais de la fonction Fréquence....

 

[JJ1]

Re : Tableau d'unités et de tranches

J'ai retrouvé...je joins le fichier où, en fait, je n'avais pas tout compris....(j'avais omis de le dire à _Ti pour ne pas le vexer!)
Pensez à avaler un Aspro dès l'ouverture du fichier!
Bon samedi

 

[JeanMarie]

Re : Tableau d'unités et de tranches

Bonjour

JJ1, j'avais vu ton poste sur Vériti, je m'y étais penché avec l'utilisation de la fonction FREQUENCE.

Comme l'avait précisé Ti, lors d'un de mes post sur Vériti, avec la fonction FREQUENCE, celle-ci rajoute un compteur "infini" à la table des "intervalles", ce qui peut poser problème.
C'est le cas ici, on doit pour réaliser la moyenne, supprimer le dernier compteur "infini" de la matrice retournée. De plus dans ton cas, il faut annalyser les écarts entre la première occurence et la dernière, il faut donc écarter les premières lignes avant la première occurence à tester, et les lignes derrières la dernière occurence.

Pas simple...

Voici ma première formule, elle est plus longue que celle de Ti, et en plus je n'ai pas mis la première condition

=MOYENNE(FREQUENCE(SI(LIGNE(1:101)>MIN(SI($A$1:$G$101=J$1;LIGNE(1:101)));SI(LIGNE(1:101)<=MAX(SI($A$1:$G$101=J$1;LIGNE(1:101)));LIGNE(1:101)));SI($A$1:$G$101=J$1;SI(LIGNE(1:101)>MIN(SI($A$1:$G$101=J$1;LIGNE(1:101)));SI(LIGNE(1:101)<=GRANDE.VALEUR(SI($A$1:$G$101=J$1;LIGNE(1:101));2);LIGNE(1:101))))))

Tu pourras remarquer, qu'il y a des conditions qui se répètent dans la détermination des deux arguments de la fonction FREQUENCE.
Ces conditions permettent de borner la zone réelle des écarts à prendre en compte.

j'essaye d'éviter au maximum, la répétition de conditions dans les formules, ou je les place dans des cellules

J'ai donc trituré dans tous les sens les écarts et les conditions.

J'ai essayé de passer par un SOMMEPROD(....)/NB.SI(....)

=SOMMEPROD(FREQUENCE(LIGNE(1:101);SI($A$1:$G$101=J$1;LIGNE(1:101)));SI(LIGNE(DECALER(A1;;;NB.SI($A$1:$G$101;J$1)+1))>1;SI(LIGNE(DECALER(A1;;;NB.SI($A$1:$G$101;J$1)+1))<=NB.SI($A$1:$G$101;J$1);1;"")))/(NB.SI($A$1:$G$101;J$1)-1)

Pour arriver à l'ultime formule

=MOYENNE(SI(LIGNE(1:101)>1;SI(LIGNE(1:101)<=NB.SI($A$1:$G$101;J$1);FREQUENCE(LIGNE(1:101);SI($A$1:$G$101=J$1;LIGNE(1:101)));"")))

JJ1, si tu as une plage importante de données (comme je le pense), dis moi si tu vois une différence de temps de calcul entre les trois formules.

@+Jean-Marie

 

[JJ1]

Re : Tableau d'unités et de tranches

Bonsoir Jean Marie, le Fil, le Forum,
Merci jean-Marie pour tes 3 formules "c'est du costaud ! félicitations!). Je te promets de les tester toutes mais à partir de jeudi car je pars en formation.
Je te donnerai l'info.
Pour la formule d'écart moyen de Tibo, elle fonctionne mais je dois vérifier au moins un résultat en comptant ligne par ligne au moins un nombre !
Merci à vous
Bonne soirée

ps: je vois que tu es sur Mac, je viens d'acheter un Imac 24 avec Numbers, tu connais ?
Moi qui ai un portable avec les 3 OS XP-Vista et Seven installés, ça change !

 

[JeanMarie]

Re : Tableau d'unités et de tranches

Re...

Numbers, c'est une série télé je crois, lol.

Plus sérieusement, je sais que ce logiciel existe, je l'ai vu en présentation sur internet, vu sur les stands Apple aux appleExpo, cela s'arrête là ma connaissance. Je ne l'ai jamais pratiqué.

J'attends avec impatient le retour d'info sur la vivacité des trois formules.

@+Jean-Marie

 

[JJ1]

Re : Tableau d'unités et de tranches

Bonjour Jean Marie, Tibo, Le Forum
Comme promis j'ai testé vos formules (pas évidentes....)

Voici les conclusions:

La formule d'écart moyen de Tibo (adaptée à ma plage):

=MOYENNE((PETITE.VALEUR(SI(($A$3:$E$200=AF$1)*LIGNE($A$3:$E$200)<>0;($A$3:$E$200=AF$1)*LIGNE($A$3:$E$200));{2;3;4})-PETITE.VALEUR(SI(($A$3:$E$200=AF$1)*LIGNE($A$3:$E$200)<>0;($A$3:$E$200=AF$1)*LIGNE($A$3:$E$200));{1;2;3})-1))

me donne un écart moyen de 12.33 et les 3 formules de Jean Marie 12.83, on va pas chipoter!
Bravo !

Concernant les 3 formules de Jean-Marie, la vitesse d'exécution est immédiate pour 7211 lignes.
je joins un exemple installé (plage RA)

Merci à vous et bon mercredi.

J'ai étendu la plage RA à A1:T7211 soit 144220 nombres, l'exécution est immédiate aussi.

ps: il faudrait peut être modifier le titre du sujet et rajouter formule écart moyen au cas où le sujet intérresserait un Excelnaute, je ne sais pas faire.

 

[JeanMarie]

Re : Tableau d'unités et de tranches

Re JJ1

Pour la différence de résultat entre la formule de Tibo et celle de Ti ou la mienne, elle est simplement dû aux nombres d'écart passer à MOYENNE, celle de Tibo ne prend en compte qu' les trois premiers écarts, celle de Ti ou la mienne, la formule prend en compte tous les écarts.

D'ailleurs je n'avais que regardé la proposition de Tibo sur la moyenne des écarts avec GRANDE.VALEUR.

Pour ton PS, demande à Pascal de le scinder en deux.

@+Jean-Marie