Suppression de lignes contenant du texte

[apfwl.87]

Bonjour

J'ai un fichier .txt que j'importe dans Excel. Ce fichier est sur plusieurs pages et à chaque début de page, j'ai les lignes de titre (sur 5 lignes). Existe-t-il un moyen de supprimer automatiquement ces lignes?

Merci d'avance pour votre aide

 

[mromain]

Re : Suppression de lignes contenant du texte

bonjour,

je te propose ce code :

Sub delRow()
Dim i As Integer
With ThisWorkbook.Sheets("Import Führ.PAX")
    For i = .Cells(.Rows.Count, 1).End(xlUp).Row To 1 Step -1
        If .Cells(i, 1).Value <> vbNullString And Not IsDate(.Cells(i, 1)) Then .Rows(i).Delete
    Next i
End With
End Sub

a+

 

[pierrejean]

Re : Suppression de lignes contenant du texte

bonjour apfwl87

teste cette macro

Sub test()
For n = Range("A65536").End(xlUp).Row To 1 Step -1
 If Range("A" & n) <> "" And Not IsDate(Range("A" & n)) Then
   Rows(n).Delete
 End If
Next n
End Sub

Edit: Salut mromain
Avais pas rafraichi !!

 

[job75]

Re : Suppression de lignes contenant du texte

Bonjour à tous,

Une solution, qui permet d'aller vite...

Sub SupprimeTitres()
Dim vide As Range
Set vide = Range("A:A").SpecialCells(xlBlanks)
For i = 5 To 1 Step -1
vide.Offset(i).EntireRow.Delete
Next
End Sub

Edit : si l'on veut supprimer aussi les lignes vide, écrire :

For i = 5 To 0 Step -1

A+

 

[apfwl.87]

Re : Suppression de lignes contenant du texte

Bonjour à tous

Woaw. Un grand merci pour votre aide si rapide et efficace. J'ai maintenant l'embarras du choix 🙂 J'ai testé les 3 et toutes fonctionnent parfaitement. C'est exactement ce dont j'avais besoin. Un grand merci et bonne journée à tous les 3.

Françoise

 

[job75]

Re : Suppression de lignes contenant du texte

Re,

Juste une petite remarque en passant.

Sur le fichier présenté par Françoise, on peut tout simplement supprimer les lignes de textes par :

Sub SupprimeTitres()
Range("A:A").SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
End Sub

Mais très souvent, sur les fichiers importés, même les dates sont des textes (et non pas des nombres) et cette macro les supprimerait aussi...

A+