Suppression automatique de colonnes vides

[emmanuel75]

Bonjour chers excelnautes,

Je n'ai pas réussi à créer une macro qui me supprimerait des colonnes vides d'un tableau afin d'obtenir "un tableau plein"...pour les courageux je transmets un exemple de mon tableau en pièce jointe...

Merci d'avance pour la moindre petite aide.

Emmanuel

 

[Compte Supprimé 979]

Re : Suppression automatique de colonnes vides

Salut Emmanuel75,

Essaye ce code ci

Sub SupColVide()
  Dim Col As Integer, DerCol As Integer
  ' Trouver la dernière colonne du tableau
  DerCol = Range("IV2").End(xlToLeft).Column
  ' De la dernière colonne vers la 3ème
  For Col = DerCol To 3
    ' Si l'entête du tableau est vide
    If Cells(2, Col).Value = "" Then
      ' On supprime la colonne
      Columns(Col).Delete
    End If
  Next Col
End Sub

A+

 

[emmanuel75]

Re : Suppression automatique de colonnes vides

Bonjour BrunoM45,

En fait, la macro se "passe", aucun message d'erreur, mais aucune colonne n'est supprimée...je ne vois pas pourquoi...le code a l'air simple et élégant...

 

[mromain]

Re : Suppression automatique de colonnes vides

bonjour,

en fait il manque un tout petit truc dans la macro de bruno :

Sub SupColVide()
  Dim Col As Integer, DerCol As Integer
  ' Trouver la dernière colonne du tableau
  DerCol = Range("IV2").End(xlToLeft).Column
  ' De la dernière colonne vers la 3ème
  For Col = DerCol To 3 [B][COLOR="Red"]Step -1[/COLOR][/B]
    ' Si l'entête du tableau est vide
    If Cells(2, Col).Value = "" Then
      ' On supprime la colonne
      Columns(Col).Delete
    End If
  Next Col
End Sub

a+

 

[Catrice]

Re : Suppression automatique de colonnes vides

Bonjour,

ci-joint une autre solution.

Sub Test()
Set MaZone = Range(Range("C2"), Range("IV2").End(xlToLeft))
If Application.CountBlank(MaZone) > 0 Then MaZone.SpecialCells(xlCellTypeBlanks).EntireColumn.Delete
End Sub

 

[emmanuel75]

Re : Suppression automatique de colonnes vides

Merci à vous tous....j'ai testé les deux macros celle de Catrice et celle de mromain çà marche très bien ...GRAND MERCI à tous...

Emmanuel

 

[vbacrumble]

Re : Suppression automatique de colonnes vides

bonjour

code adapté de celui que donne l'enregistreur de macro 😉

Sub Macro1()
ActiveSheet.UsedRange.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlToLeft
End Sub

 

[Catrice]

Re : Suppression automatique de colonnes vides

vbacrumble,

Sub Macro1()
ActiveSheet.UsedRange.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlToLeft
End Sub

Attention avec cette méthode, s'il y a des cellules vides dans les colonnes => surprises 😀

Voir le fichier joint

 

[vbacrumble]

Re : Suppression automatique de colonnes vides

Re, bonjour Catrice


Houps !

Merci de m'avoir signalé la chose 😉