sommeprod

[JC de Lorient]

Bonjour le forum

Dans une feuille j'ai un tableau auquel est rajouté une ligne tous les mois, ce tableau va de la colonne A a AY

En colonne A j'ai des dates au format mmmm/aaaa

tous les trimestres j'ai un calcul de montant a faire sur un cumul sur la colonne AP

j'entre ma demande par mois de début et mois de fin de période

je sais que la fonction est SOMMEPROD mais malgré mes recherches et divers essais j'ai tjrs 0 en résultat

Donc si mon début de période est Janvier et la fin est Mars je souhaiterais qu'excell me calculle la somme de la colonne AP sur Janv, Févr et mars

j'espère avoir été assez clair pour que quelqu'un puisse me fournir la formule magique !!!

Merci a vous

JC

 

[Jean-Marie]

Bonjour JC

Fil de départ, avec une réponse en fin de fil avec la fonction SOMMEPROD
Lien supprimé

Avec plusieurs mois (du début de janvier à fin avril) =SOMMEPROD((MOIS(A1:A100)>1)*(MOIS(A1:A100)<5)*AY1:A100)
La fonction SOMMEPROD n'aime pas les colonnes entières.

JC, il serait bon de garder le même fil de discussion. Si la proposition de la fonction n'a pas réussi à résoudre ton problème, il serait judicieux de placer un fichier pour nous éclairer sur les données que tu as dans tes colonnes.

@+Jean-Marie

 

[JC de Lorient]

Bonjour le forum

j'ai toujours des soucis avec SOMMEPROD mais y'a du mieux je n'ai plus de message d'erreur, par contre mon résultat est de zéro alors que j'attends un nombre particulier

voici ma formule :
SOMMEPROD((MOIS(Récap!A4:A100)>=MOIS(M4)*(MOIS(Récap!A4:A100)<=MOIS(M6)*Récap!AP4:AP100)))

M4 et M6 étant des cellules au format jj/mm/aaaa
Récap!A4:A100 étant une cclonne au format jj/mm/aaaa
Récap!AP4:AP100 étant ma colonne de chiffre a calculer

ou est l'erreur ?

Merci de pouvoir me venir en aide

JC

 

[Jean-Marie]

Re

Attention au positionnement des parenthèses

SOMMEPROD((MOIS(Récap!A4:A100)>=MOIS(M4))*(MOIS(Récap!A4:A100)<=MOIS(M6))*Récap!AP4:AP100)

@+Jean-Marie

 

[JC de Lorient]

Bonjour Jean Marie

merci bcp ça marche très bien maintenant et tout ça pour juste une histoire de parenthèses !!!!

merci mille fois et bon dimanche

JC

 

[JC de Lorient]

re le forum, Jean Marie

suis tjrs a la ramasse avec SOMMEPRO Je viens de fouiller sur les fils notamment de Céléda mais j'en attrape mal au crâne (je crois que je m'y ferai jamais a cette fonction)

j'ai oublié un argument : prendre aussi en considération l'année de M4 et M6. Alors ma question est : comment et ou insérer l'argument année?

=SOMMEPROD((MOIS(Récap!$A$4:$A$500)>=MOIS($M$4))*(MOIS(Récap!$A$4:$A$500)<=MOIS($M$6))*Récap!$AP$4:$AP$500)

merci une nouvelle fois

JC

 

[JC de Lorient]

re le forum

g essayé qquchose qui a l'air de marcher :

=SOMMEPROD(((MOIS(date)>=MOIS($M$4))*(MOIS(date)<=MOIS($M$6)))*(((ANNEE(date)>=ANNEE($M$4))*((ANNEE(date)<=ANNEE($M$6))))*Récap!$AP$4:$AP$500))

Peut etre y a t il moyen de simplifier a voir !!

suis hyper content sur ce coup là je me suis débrouillé (presque) seul

merci le forum

JC

 

[Jean-Marie]

Re...

Pourquoi décomposer le mois et l'année. Compare la date de début de mois et de fin de mois, la formule sera plus courte.

exemple de formule =SOMMEPROD((A1:A100>=DateDébut)*(A1:A100<=DateFin)*AY1:A100)

La fonction FIN.MOIS() de la macro complémentaire Utilitaire d'analyse, te retournera la date de fin en fonction de la date et du nombre de mois.
=FIN.MOIS(DateDébut;3)

exemple de formule =SOMMEPROD((A1:A100>=DateDébut)*(A1:A100<=FIN.MOIS(DateDébut;3))*AY1:A100)

@+Jean-Marie

 

[JC de Lorient]

Re Jean Marie, le forum

en effet cette formule est bcp plus simple et fonctionne a merveille

merci bcp Jean Marie

JC