XL 2013 Somme.SI douze dernières valeurs (selon date

[maubon]

Bonjour,

Je cherche à calculer, sur l'onglet 1, la somme des 12 dernières valeurs du site selon les valeurs présentes (onglet 2).
CF fichier joint

Pourriez vous m'aider?
Merci

 

[sylvanu]

Bonjour Maubon,

J'ai supposé que les dates sont en ordre croissant et que les 12 plus récentes valeurs sont les douze dernières.

Essayez cela :

=SOMME(DECALER('2'!C1;NB('2'!C:C);0;-12))

C:C colonne à sommer
C1 première cellule de la colonne
12 nombre de cellules à compter

 

[maubon]

Super mais auriez vous une formule matricielle qui permettrait de garder les calcul via les liens du tableau du type [@[x]?

 

[sylvanu]

Pourquoi matricielle, la formule s'adaptera en fonction du tableau si elle est écrite de cette façon :

=SOMME(DECALER(BASE_DE_DONNEES24[[#En-têtes];[CONSO - TOTAL]];NB(BASE_DE_DONNEES24[[#Tout];[CONSO - TOTAL]]);0;-12))

 

[R@chid]

Bonsoir @ tous,
en B3 :

=SOMME(DECALER(BASE_DE_DONNEES24[[#En-têtes];[CONSO - TOTAL]];EQUIV([@SITE];BASE_DE_DONNEES24[N° RAE])-11;;12))

Cordialement

 

[maubon]

Bonjour,
Merci pour votre abnégation, en revanche il faudrait intégrer une condition somme.si, en effet, il peut s'agir du point 1 ou 2.
Ca complique encore la réflexion...

 

[sylvanu]

Bonjour,
Il fallait poser la bonne question au premier post. Cela eut évité de réfléchir pour rien.

 

[mapomme]

Bonjour @maubon, @sylvanu 🙂, @R@chid 🙂,

Un essai avec une base qui n'a pas besoin d'être triée ni par date ni par site. La formule en B3 est matricielle.

=SOMME.SI.ENS(BASE_DE_DONNEES24[CONSO - TOTAL];BASE_DE_DONNEES24[N° RAE];REFERENTIEL[[#Cette ligne];[SITE]];BASE_DE_DONNEES24[DATE];">=" & GRANDE.VALEUR((BASE_DE_DONNEES24[N° RAE]=REFERENTIEL[[#Cette ligne];[SITE]])*BASE_DE_DONNEES24[DATE];12))

Formule Matricielle:

• à valider par la combinaison des trois touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée
• ne pas entourer la formule d'accolade au clavier. C'est la validation par Ctrl+Maj+Entrée qui ajoute les accolades
• une fois saisie et validée, une formule matricielle peut être copiée et collée
• à chaque édition/modification de la formule matricielle, penser à la valider par Ctrl+Maj+Entrée

 

[maubon]

Merci beaucoup, la dernière formule fonctionne très bien