Microsoft 365 Rechercher date

[Ines99]

Bonsoir le Forum,
Pourriez-vous m'aider à trouver le vb pour récupérer la date de chaque opération bancaire en tenant compte du montant Debit ou Credit, du Nom du fournisseur et du numéro de la facture ?
Ci-joint le fichier test
Merci d'avance pour votre aide
Ines

 

[Phil69970]

Bonjour @Ines99

Je te propose ce fichier

Merci de ton retour

 

[Lolote83]

Bonjour à toutes et à tous,
Voici le fichier en retour.
Des tableaux structurés ont été construits et 2 colonnes rajoutées (CONCAT)
Du coup, une simple formule permet de récupérer la date
Cordialement
@+ Lolote83

 

[Hecatonchire]

Bonjour à toutes et à tous,

Passage du tableau en feuille Banque en tableau structuré

2 versions :
Version 1 : Si doublons on a l'erreur #Prolongation sauf pour la dernière ligne (affichage des doublons)

=FILTRE(Tableau1[EcritureDate];(Tableau1[PieceRef]=Fournisseurs!D3)*(Tableau1[Nom Fournisseur]=Fournisseurs!H3)*((Tableau1[Debit]+Tableau1[Credit])=Fournisseurs!F3);"Pas de correspondance")

Version 2 : Si doublons on a le texte "Doublons"

=LET(mr;FILTRE(Tableau1[EcritureDate];(Tableau1[PieceRef]=Fournisseurs!D3)*(Tableau1[Nom Fournisseur]=Fournisseurs!H3)*((Tableau1[Debit]+Tableau1[Credit])=Fournisseurs!F3));nb;NB(mr);SI(nb=0;"Pas de correspondance";SI(nb=1;mr;"Doublons")))

 

[sylvanu]

Bonjour tout le monde,
Ou encore avec cette formule :

=SIERREUR(INDEX(Banque!$D$5:$D$600;EQUIV(D3&F3&H3;Banque!$I$5:$I$600&Banque!$N$5:$N$600&Banque!$L$5:$L$600;0));SIERREUR(INDEX(Banque!$D$5:$D$600;EQUIV(D3&F3&H3;Banque!$I$5:$I$600&Banque!$M$5:$M$600&Banque!$L$5:$L$600;0));""))

A valider en matriciel pour les anciennes versions XL.

 

[Ines99]

Bonjour le Forum,
Merci beaucoup,
Je vais tester les solutions sur mon jeux de données.
Il peut effectivement y avoir des problématiques de gestion de doublons, et autres..
Je vous fais un retour
Merci
Ines