Somme de chiffres qui compose un mot (4 lettres)

[starz]

Bonjour,
Pouvez vous m'aider à résoudre mon problème de formule auto.

Je souhaiterai calculer la somme des chiffres qui compose un mot de 4 lettres, par exemple M3G1 = 4 dans 2 cellules et affiché dans une autre cellule la somme la plus élevé des 2.

Si A2=4 et C2=2 alors B2=4 (car A2>C2)

Je joins un fichier pour faciliter la tâche.

Merci

 

[Victor21]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour, starz

A tout hasard, et compte tenu de ce que j'ai pû comprendre, en B2 :

=MAX(TEXTE(STXT(A2;2;1);0)+TEXTE(STXT(A2;4;1);0);TEXTE(STXT(C2;2;1);0)+TEXTE(STXT(C2;4;1);0))

 

[JBOBO]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,

Une solution basique avec un tableau annexe, pas des plus elegante mais qui fonctionne!

 

[KenDev]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour Starz, Victor,

Avec l'hypothèse que les seuls cas possibles sont présent dans le fichier (c.à.d Lettre-Chiffre-Lettre-Chiffre OU Lettre-Chiffre OU vide) une autre proposition :
en B2 :

=MAX(CNUM(DROITE(GAUCHE(A2&REPT("0";4-NBCAR(A2));2);1))+CNUM(DROITE(A2&REPT("0";4-NBCAR(A2));1));CNUM(DROITE(GAUCHE(C2&REPT("0";4-NBCAR(C2));2);1))+CNUM(DROITE(C2&REPT("0";4-NBCAR(C2));1)))

Cordialement

KD

Edit : bonjour Jbobo

 

[CHALET53]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour Starz, Victor,

Cela suppose (et c'est peut-être le cas) que les nombres soient toujours en position 2 et 4. Pour C3, la formule ne fonctionne pas : pas de valeur en position 4

Je propose une solution batarde avec des colonnes qui peuvent être cachées

Ou alors en VBA

a+

 

[hoerwind]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour, salut les autres,

En B2 :

=MAX(SI(NBCAR(A2);STXT(A2;2;1);0)+SI(NBCAR(A2)>3;STXT(A2;4;1);0);SI(NBCAR(C2);STXT(C2;2;1);0)+SI(NBCAR(C2)>3;STXT(C2;4;1);0))

formule à copier vers le bas

 

[Monique]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,

à essayer :

=SOMME(SI(ESTNUM(STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1);STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1))

Formule matricielle, à valider par ctrl, maj et entrée

 

[Monique]

Re : Somme de chiffres qui compose un mot (4 lettres)

Re,

Plus court si seulement 4 caractères

=SOMME(SI(ESTNUM(STXT(A2;{1;2;3;4};1)*1);STXT(A2;{1;2;3;4};1)*1))

Formule matricielle, à valider par ctrl, maj et entrée

 

[david84]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,
en attendant plus court :

=MAX(SOMME(SI(ESTNUM(CHERCHE(1;A2));1);SI(ESTNUM(CHERCHE(2;A2));2);SI(ESTNUM(CHERCHE(3;A2));3);SI(ESTNUM(CHERCHE(4;A2));4);SI(ESTNUM(CHERCHE(5;A2));5);SI(ESTNUM(CHERCHE(6;A2));6);SI(ESTNUM(CHERCHE(7;A2));7);SI(ESTNUM(CHERCHE(8;A2));8);SI(ESTNUM(CHERCHE(9;A2));9));SOMME(SI(ESTNUM(CHERCHE(1;C2));1);SI(ESTNUM(CHERCHE(2;C2));2);SI(ESTNUM(CHERCHE(3;C2));3);SI(ESTNUM(CHERCHE(4;C2));4);SI(ESTNUM(CHERCHE(5;C2));5);SI(ESTNUM(CHERCHE(6;C2));6);SI(ESTNUM(CHERCHE(7;C2));7);SI(ESTNUM(CHERCHE(8;C2));8);SI(ESTNUM(CHERCHE(9;C2));9)))

A+

Edit : Ben Monique a fait plus court🙂, mais si j'ai bien compris, en adaptant la formule de Monique :

=MAX(SOMME(SI(ESTNUM(STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1);STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1));SOMME(SI(ESTNUM(STXT(C2;LIGNE(INDIRECT(1&":"&NBCAR(C2)));1)*1);STXT(C2;LIGNE(INDIRECT(1&":"&NBCAR(C2)));1)*1)))

ou sur 4 caractères

=MAX(SOMME(SI(ESTNUM(STXT(A2;{1;2;3;4};1)*1);STXT(A2;{1;2;3;4};1)*1));SOMME(SI(ESTNUM(STXT(C2;{1;2;3;4};1)*1);STXT(C2;{1;2;3;4};1)*1)))

 

[starz]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour et merci à tous pour vos réponse !
J'ai testé la formule matricielle de Monique en premier et ça fonctionne.
Cependant, honte à moi, j'ai oublié une chose dans ma demande :
Il y a un coef multiplicateur à rajouter pour certaine ligne - bien souvent quand on doit multiplier on n'a pas besoin de comparer les cellules.

Je rejoins mon exemple à jour, je pense que c'est plus clair.

Merci

starz

 

[hoerwind]

Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour, salut les autres,

Proposition de formule non matricielle sous la pièce jointe

 

[starz]

Re : Somme de chiffres qui compose un mot (4 lettres)

Merci ça fonctionne parfaitement !