Si cellule contient la lettre "D" alors...

[jbdubreuil]

Bonjour,

J'ai decouvert ce forum il y a qq jours et j'avoue etre impressionné par la qualité de ce site. J'en profite donc pour apprendre et approfondir mes connaissance en Xcel... Voici un petit probleme:

J'ai une cellule (a1) avec du texte
J'aimerais une formule qui puisse me dire si la cellule (a1) contient la lettre "D".

Pour le moment, j'utilise la fonction suivante qui marche tres bien (en anglais):
=Search("d";a1) qui me donne la position de la lettre "d" dans la cellule...ou #VALUE si la cellule ne contient pas la lettre "d".
J'imbrique ensuite une autre fonction, if(iserror(search("d";a1));"NON";"OUI")

Y aurait il une autre formule?

 

[Tibo]

Re : Si cellule contient la lettre "D" alors...

Salut,

In french :

possibilité de replacer par :

=SI(ESTNUM(CHERCHE("d";B11));"OUI";"NON")

En version anglaise, je sais pas trop. Je pense que la traduction ne devrait pas être trop compliquée.

@+

 

[Monique]

Re : Si cellule contient la lettre "D" alors...

Bonjour,

Pour gagner 2 caractères, en angliche :
=IF(ISERR(SEARCH("d",A1)),"non","oui")

 

[andré]

Re : Si cellule contient la lettre "D" alors...

Salut,

C'est une façon de faire.

Une autre consiste à compter le nombre de caractères du texte et le commparer au même texte dont la lettre cherchée a été supprimée.

=NBCAR(A1)<>NBCAR(SUBSTITUE(A1;"D";"")

Si la formule renvoie VRAI c'est que la lettre D est présente.

Â+

 

[pimsjaune]

Re : Si cellule contient la lettre "D" alors...

Moi j'ai le même style de problème sauf que ma formule doit ressembler à:
si(cellule contient "mot" ou si la cellule est vide alors oui ou non)
Et je n'y arrive pas sachant que certaines cellules contiennent plusieurs mots et que d'autres sont vides.
Je voudrais avoir en résultat les cellules qui n'ont ni ce mot et qui ne sont pas vides..
Merci
En espérant avoir été clair.

 

[cerpo]

Re : Si cellule contient la lettre "D" alors...

J'arrive un peu après la bataille, mais si ça peut aider quelqu'un...
Pour trouver un mot donné ou une cellule vide, juste une petite adaptation :

=SI(OU(ESTNUM(CHERCHE("mot";A1));A1="");"OUI";"NON")

Le tout avec le mot recherché, évidemment.

 

[Emeric82]

Bonjour,
Je sollicite un coup main pour un complément sur un sujet lié aux posts précédents mais qui ne mérite peut-être pas d'ouvrir un post spécifique.
J'utilise la fonction SOMME PROD qui m'indique donc la somme du produit entre 2 colonnes, dans mon exemple, si j'ai "OK" dans la première colonne et une croix dans la seconde alors je somme :
=SOMMEPROD((A5:A13="x")*((B5:B13)="OK"))
Les personnes qui ont utilisé le fichier ont ajouté un commentaire dans la même cellule qui contient le "ok", j'ai donc des cellules avec "OK Paul" , ou "OK Isabelle". La condition de ma formule précédente ne fonctionne plus . Il faut donc que je modifie ma condition pour savoir si dans la cellule concernée apparait le mot "ok",
L'idée d'utiliser l'astuce ="*OK*" (au lieu de ="OK") ne fonctionne pas avec les symboles logique =, >, < ... (dommage) ;
d'où l'idée d'utiliser la fonction :
=SI(ESTNUM(CHERCHE("d";B11));"OUI";"NON")
J'essai de l'adapter :
=SOMMEPROD((A4:A12="x")*(SI(ESTNUM(CHERCHE("*OK*";B4:B12));"OK";"1")="OK"))
Mais sans succès car la fonction indique tout le temps le résultat "0" ; pourtant en cliquant sur l'icone "Fx" , on voit le calcul réalisé en détail et là, le résultat est correct !.

Si quelqu'un sait corriger ma formule ou proposer une autre solution je suis preneur (je précise que je ne peux pas créer de colonne, je dois donc être capable de détecter "ok" dans les cellules concernée). En PJ l'Excel avec l'exemple. Merci ;-) .

 

[Dranreb]

Bonjour
Comme ça :

=SOMMEPROD((A4:A12="x")*ESTNUM(CHERCHE("OK";B4:B12)))

ou simplement comme ça :

=SOMMEPROD((A4:A12="x")*(GAUCHE(B4:B12;2)="OK"))

 

[chris]

Bonjour à tous

=NB.SI.ENS(A4:A12;"x";B4:B12;"OK*")

devrait aussi fonctionner

 

[Emeric82]

Super, génial, "énormissime" ! Merci bcp, toujours aussi efficace les membres du forum ;-)
(j'ai l'impression que vous avez mis 10 secondes à faire la formule là où j'y ai passé quelques heures sans succès).

 

[Lily78]

Bonjour,

Je me permets d'utiliser ce post car il est en continuité de ma recherche.

J'ai utilisé la fonction ESTNUM pour un tableau de suivi des absences, mon tableau contient des liaisons avec un autre fichier afin d'éviter des doubles saisies.
=SI(ESTNUM(CHERCHE("JM";'fichier source'!E$4));7;"")
J'ai désormais besoin d'une formule plus précise :
Exemple : le fichier source indique 5 JM
Je veux modifier la formule afin de trouver le mot JM dans la cellule et si oui qu'elle recopie uniquement le chiffre présent dans la cellule et non le mot JM.

Est-ce possible ?

Merci par avance.

 

[JHA]

Bonjour à tous,

Si ton chiffre est situé à gauche
=SI(ESTNUM(CHERCHE("JM";'fichier source'!E$4));gauche(E$4;1);"") ou
=SI(ESTNUM(CHERCHE("JM";'fichier source'!E$4));gauche(E$4;2);"")*1

JHA

 

[Lily78]

Bonjour,

Merci pour ce retour. Je ne connaissais pas cette subtilité.
Toutefois, j

e ne peux pas définir à l'avance ​

le chiffre à recopier qui peut aller de 1 à 7.
😛Suis-je assez claire ?

 

[job75]

Bonjour Lily78, JHA,

A priori ceci devrait faire l'affaire =REPT(GAUCHE(A1);DROITE(A1;2)="JM")

ou pour remplacer le texte par un nombre =SIERREUR(--REPT(GAUCHE(A1);DROITE(A1;2)="JM");"")

Remplacez A1 par la référence de cellule que vous voulez.

A+

 

[JHA]

Bonjour à tous,
Bonjour Job75 🙂

La fonction GAUCHE('fichier source'!E$4;1) te retournera le premier chiffre de ta donnée en "E4" qu'il soit 0;1;2;.....8;9

JHA