séparer une ligne en plusieurs

[vincenus33]

Bonjour,

voilà mon problème.

j'ai un fichier excel avec plusieurs lignes. dans la colonne G, j'ai plusieurs valeurs.
par exemple en colonne G, je peux avoir AAA, BBB, CCC. A chaque nouvelle valeur, il y a un renvoi à la ligne.
Je souhaiterai du coup couper, en fonction du nombres de valeurs en G, en x lignes (ligne 1 avec en G, AAA, ligne 2, BBB et ligne 3 CCC en G) en conservant les données des colonnes A à F et des autres après G.
si c'est plus simple, la conversion peut se faire dans un autre onglet, aucun problème pour moi.

MERCI pour votre aide

j'ai joints un fichier normalement!

 

[job75]

Re : séparer une ligne en plusieurs

Bonjour vincenus33,

Voyez cette macro dans le fichier joint (clic droit sur l'onglet Sépare et Visualiser le code) :

Private Sub Worksheet_Activate()
Dim tablo, i&, u&, h&, col%, s, j&, n&, k%
With Sheets("Base") 'nom à adapter
  tablo = .Range("A1:H" & .Cells(.Rows.Count, "G").End(xlUp).Row)
End With
If UBound(tablo) > 1 Then
  '--détermination de la hauteur---
  For i = 2 To UBound(tablo)
    u = UBound(Split(tablo(i, 7), vbLf))
    h = h + IIf(u < 0, 1, u + 1)
  Next
  '---remplissage du tableau---
  col = UBound(tablo, 2)
  ReDim R(1 To h, 1 To col)
  For i = 2 To UBound(tablo)
    s = Split(tablo(i, 7), vbLf)
    u = UBound(s)
    j = IIf(u < 0, 1, u + 1)
    For j = 1 To j
      n = n + 1
      For k = 1 To col
        R(n, k) = tablo(i, k)
      Next
      If u >= 0 Then R(n, 7) = Trim(s(j - 1))
    Next
  Next
  [A2:H2].Resize(n) = R
End If
Range("A" & n + 2 & ":H" & Rows.Count).ClearContents
End Sub

Elle se déclenche quand on active la feuille et elle est très rapide sur un grand tableau.

A+

 

[job75]

Re : séparer une ligne en plusieurs

Re,

Pour les bordures, on peut appliquer une Mise en forme conditionnelle (MFC) sur les colonnes A:H.

Edit : j'ai aussi légèrement simplifié la macro :

j = IIf(u < 0, 0, u)
For j = 0 To j
  n = n + 1
  For k = 1 To col
    R(n, k) = tablo(i, k)
  Next
  If u > 0 Then R(n, 7) = Trim(s(j))
Next

Fichier (2).

A+