Microsoft 365 sauvegarder les données d'un planning sur un nouvel onglet

[lathus jean-claude]

bonjour
J'ai un planning perpétuel sur 18 mois ou je renseigne mes heures de travail
je voudrais que lorsque je change l'année en A1 que ca enregistre mon planning sur un nouvel onglet et qui vide la nouvel année
est il possible de le faire ci joint mon planning
merci d'avance de vos réponse

 

[job75]

Bonsoir lathus jean-claude,

On pourrait certainement faire quelque chose si dans les feuilles Jean-Claude et Nathalie il n'y avait qu'une seule année avec12 mois.

Revoyez votre fichier.

A+

 

[lathus jean-claude]

bonsoir je vous envois un fichier modifier 12 mois par année

 

[job75]

Voyez le fichier joint et la macro dans ThisWorkbook :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If Right(Sh.Name, 4) Like "####" Or Target.Address <> "$A$1" Then Exit Sub
Dim memAn, nf$
memAn = Sh.[A1] 'mémorise l'année
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
Application.Undo 'annule l'entrée
If Not Sh.[A1] Like "####" Then GoTo 1
Target.Select
nf = Sh.Name & " " & Sh.[A1] 'nom pour l'archive
If MsgBox("Voulez-vous créer l'archive '" & nf & "' ?", vbYesNo) = vbNo Then GoTo 1
'---crée l'archive---
Application.DisplayAlerts = False
On Error Resume Next 'si la feuille n'a pas été créée
Sheets(nf).Delete
Sheets.Add Before:=Sh 'nouvelle feuille
ActiveSheet.Name = nf 'nomme la feuille
Sh.Cells.Copy ActiveSheet.[A1] 'copie tout
Sh.[A1].Copy ActiveSheet.[A1] 'allège la mémoire
ActiveSheet.UsedRange = Sh.UsedRange.Value 'supprime les formules
'---réinitialise---
With Sh.[8:38].SpecialCells(xlCellTypeConstants)
    .Value = ""
    .Interior.ColorIndex = xlNone
End With
'---restitue l'année---
1 Sh.[A1] = memAn
Sh.Activate
Application.EnableEvents = True 'réactive les évènements
End Sub

Elle se déclenche quand on modifie la cellule A1 des feuilles non archivées.

Testez en entrant 2022 dans la feuille Jean-Claude et 2023 dans la feuille Nathalie.

PS : j'ai supprimé les SpinButtons qui sont guère utiles et peu commodes.

Bonne nuit.

 

[lathus jean-claude]

bonjour job75
merci beaucoup cela fonctionne très bien comme je le souhaitais je suis loin de vos connaissances Excel vba. désolé de ne pas vous avoir répondu plus tôt
grand merci