Microsoft 365 Résultat #DIV/0! avec fonction si erreur avec formule moyenne

[Maya3375]

Bonjour,
J'ai dans une cellule la formule =MOYENNE(SI(ESTERREUR($L12:$Q12);"";($L12:$Q12))).
Cela fonctionne si j'ai au minimum une cellule complétée sur les 6.
Par contre, j'obtiens le résultat #DIV/0! si toutes mes cellules ont un résultat "VALEUR!.
Comment afficher un résultat vide dans ce cas svp ?
Merci de prendre le temps de me répondre.
Cordialement,
Maya

 

[C'est papy Mougeot !]

Bonjour,
S'il y a l'erreur #VALEUR! dans les cellules c'est qu'il y a un problème en amont.
Connaissez-vous la cause de ces erreurs? Je pense qu'elles sont le résultat d'une formule.

 

[job75]

Bonjour Maya3375, papy,

Utilsez la formule =SIERREUR(MOYENNE($L12:$Q12);"")

A+

 

[Maya3375]

Bonjour,
S'il y a l'erreur #VALEUR! dans les cellules c'est qu'il y a un problème en amont.
Connaissez-vous la cause de ces erreurs? Je pense qu'elles sont le résultat d'une formule.

Bonjour, oui effectivement, j'ai parfois un résultat VALEUR! sur le résultat de la formule suivante:
=(SI(ESTVIDE(INDEX(Suivis!$B$35:$U$64;EQUIV($C12;Suivis!$B$35:$B$64;0);EQUIV(N$8;Suivis!$B$2:$U$2;0)))=VRAI;" ";INDEX(Suivis!$B$35:$U$64;EQUIV($C12;Suivis!$B$35:$B$64;0);EQUIV(N$8;Suivis!$B$2:$U$2;0))))/N$6

parce qu'elles sont le résutat de 6 cellules dont certaines d'entre elles sont vides mais je n'arrive pas à ajouter si est vide alors rien dans ma formule...

Parce que, ensuite, je dois avoir la moyenne de mes 6 cellules uniquement sur celles qui ne sont pas vides.
Avec la formule =MOYENNE(SI(ESTERREUR($L14:$Q14);"";($L14:$Q14))), cela fonctionne si j'ai au minimum une cellule complétée (Excel prend bien en compte la moyenne de cette seule cellule) mais si j'ai VALEUR sur les 6 cellules, j'ai DIV0, ce qui n'est pas top sur un compte rendu

J'espère être claire...

 

[Maya3375]

Bonjour Maya3375, papy,

Utilsez la formule =SIERREUR(MOYENNE($L12:$Q12);"")

A+

Bonjour,
Alors, dans ce cas, si j'ai 3 cellules avec des valeurs et 3 cellules avec #VALEUR! il ne m'affiche aucun résultat (alors qu'il me faut la moyenne des 3 cellules)

 

[JHA]

Bonjour à tous,

Peux-tu nous joindre un exemple sur fichier?

JHA

 

[sylvanu]

Bonjour Maya, JHA,
Si j'ai bien compris :
Dans vos 6 cellules dont vous voulez faire la moyenne, alors faites :

=SIERREUR(Votre formule;"")

( "Votre formule" étant la formule initiale dans la cellule )
Idem pour la cellule Moyenne.
Ainsi les #Valeur! disparaitront, il ne fera la moyenne que sur les cellules significatives.
Un ex en PJ.

 

[job75]

Bonjour,

=SIERREUR(MOYENNE(SI(ESTNUM($L12:$Q12);$L12:$Q12));"")

Validation normale sur Office 365.

Validation matricielle par Ctrl+Maj+Entrée sur Excel 2019 et versions antérieures.

A+

 

[Maya3375]

Bonjour Sylvanu, Bonjour XLDnaute Barbatruc,

Excellent !!! Vos 2 formules fonctionnent ! Me voilà avec un tableau tout beau, tout propre ! ;-)
Merci infiniment !!

Belle journée !!

Maya