Résulta #n/a qui me gène

[tuonoman]

Bonjour a tous

Sue cette formule

=(RECHERCHEV(C14;$C$2:$D$4;2;FAUX)*C15)+(RECHERCHEV(D14;$C$2:$D$4;2;FAUX)*D15)+(RECHERCHEV(E14;$C$2:$D$4;2;FAUX)*E15)

Comme je peux ne pas avoir de valeur sur les cellules E15 et D15 et C15. Je me retrouve avec un #N/A.

Comment puis-je faire pour ne pas avoir cette erreur.

Merci a tous

 

[antha]

Re : Résulta #n/a qui me gène

Bonjour !

Sans fichier joint, l'une des solutions dans ce genre de cas est de faire =

=si(esterreur(taformule);;taformule)

==> Si la formule renvoie une erreur alors ne rien faire, sinon exécuter la formule.

Tu peux faire le meme genre de test juste sur les cellule potentiellement vides (=si(estvide(E15);;E15))

 

[Raja]

Re : Résulta #n/a qui me gène

Bonjour,

C'est un peu long , mais essaye toujours la formule suivante :

=SI(ESTNA(RECHERCHEV(C14;$C$2:$D$4;2;FAUX));0;RECHERCHEV(C14;$C$2:$D$4;2;FAUX)*C15)+SI(ESTNA(RECHERCHEV(D14;$C$2:$D$4;2;FAUX));0;RECHERCHEV(D14;$C$2:$D$4;2;FAUX)*D15)+SI(ESTNA(RECHERCHEV(E14;$C$2:$D$4;2;FAUX));0;RECHERCHEV(E14;$C$2:$D$4;2;FAUX)*E15)

Comme disait antha, si on a ton fichier une autre solution est possible.

 

[tuonoman]

Re : Résulta #n/a qui me gène

Voici le fichier

merci a vous

 

[abcd]

Re : Résulta #n/a qui me gène

Bonjour,

A essayer :
=SI(C14*D14*E14=0;"";(RECHERCHEV(C14;$C$2:$D$4;2;FAUX)*C15)+(RECHERCHEV(D14;$C$2:$D$4;2;FAUX)*D15)+(RECHERCHEV(E14;$C$2:$D$4;2;FAUX)*E15))

abcd

 

[Raja]

Re : Résulta #n/a qui me gène

Re,

Essaye la formule suivante et recopie vers le bas :

=SOMMEPROD((C10:E10=$C$2:$C$4)*(C11:E11*$D$2:$D$4))

édit : salut abcd

 

[tuonoman]

Re : Résulta #n/a qui me gène

Intéressant comme formule serait tu m’expliqué ça logique.
Car l’aide de Excel est très succincte
Florent

 

[tuonoman]

Re : Résulta #n/a qui me gène

Voici une version +/- définitive d’une partie du devis. Néant moin je viens de m’apercevoir d’un problème.
Sur une puissance indiquée de 250 Watts, j ne trouve pas de solution a 260 watt, hors celle-ci est la + économique. ( 106 € pour 2 alim de 100 watts + 1 alim de 60 watt)
Quelqu’un a t’il une solution a mon problème.

Merci par avance de votre aide

 

[Raja]

Re : Résulta #n/a qui me gène

Re,

Ce n'est pas évident, mais je vais tenter d'expliquer. J'espères que tu connaît un peu les calculs matriciels.

La formule SOMMEPROD est une fonction matricielle puissante. Ceci étant précisé, il y a notamment deux manières d'utiliser cette fonction. Plus souvent, je l'utilise sous cette forme suivante (chaque forme à son utilité) :

=SOMMEPROD((critère1)*(critère2)*(critèreN))

plutôt que sous cette forme :

=SOMMEPROD((critère1);(critère2);(critèreN))

Les signes + ou / peuvent être utilsé dans la formule selon le cas. Les critères peuvent être beaucoup plus complexes qu'un simple test et quant à la forme de la formule on peut faire un mélange de de ces 2 formes principales comme suivant :

=SOMMEPROD((critère1)*(critère2);(critère3)*(critère4))

ou bien

=SOMMEPROD((critère1)*((critère2)+(critère3))

Cela dépendra l'analyse d'un problème posé.

Pour revenir à notre problème la formule à mettre, plutôt sous la forme SOMMEPROD((critère1)*(critère2)), dans la ligne 11 est celle-ci :

=SOMMEPROD((C10:E10=$C$2:$C$4)*(C11:E11*$D$2:$D$4))

Le premier critère (C10:E10=$C$2:$C$4) de la fonction compare la plage C10:E10 à la plage $C$2:$C$4. Le résutat de ce calcul est une matrice booléenne(VRAI=1 ou FAUX=0) de 3 lignes et 3 colonnes suivante :

1	0	0
0	1	0
0	0	1

La deuxième partie (C11:E11*$D$2:$D$4)) de la fonction multiplie la plage C11:E11 par la plage $D$2:$D$4. Le résultat est encore une matrice de valeurs de 3 lignes et 3 colonnes.

38	0	38
30	0	30
19	0	19

En multipliant à nouveau ces deux matrices on obtient la matrice suivante et la somme de ces valeur donne le résultat escompté.

1	0	0		38	0	38		38	0	0
0	1	0	x	30	0	30	=	0	0	0
0	0	1		19	0	19		0	0	19

J'espères que tu as compris mon explication.

 

[Raja]

Re : Résulta #n/a qui me gène

Re,

Si tu multiplie les valeurs de la colonne G (Puissance) par les valeurs de la colonne I (Coût total) dans la colonne J et tu prendra la plus petite valeur de cette colonne J (peut être par une fonction MIN ou PETITE.VALEUR, celui-ci sera le coût à retenir.

 

[tuonoman]

Re : Résulta #n/a qui me gène

Sur cette formule
=SI(ET(MOD($F$4-(C12*C11);C11)<=D11;MOD($F$4-(C12*C11);C11)>(2*E11));ARRONDI.SUP(($F$4-(C12*C11))/D11;0);ARRONDI.INF(($F$4-(C12*C11))/D11;0))

figurant en D12 sur le tableau joint + haut. Comment puis je faire pour que si la valeur et négative celle-ci soit rendu a un résulta 0 ou neant.

merci de votre aide

 

[Raja]

Re : Résulta #n/a qui me gène

Re,

Essaye la formule suivante :

=SI(D11;SI(ET(MOD($F$4-(C12*C11);C11)<=D11;MOD($F$4-(C12*C11);C11)>(2*E11));ARRONDI.SUP(($F$4-(C12*C11))/D11;0);ARRONDI.INF(($F$4-(C12*C11))/D11;0));0)

PS : Le message d'erreur "#DIV/0" vient du fait que la cellule juste au-dessus de la cellule de la formule est parfois à la valeur zéro

 

[jeanpierre]

Re : Résulta #n/a qui me gène

Bonsoir à tous,

Pour ce faire, il faut doubler ta formule avec : SI(taformule <=0;"" ou 0 si tu veux; sinon taformule)

Vois si cela te convient.

Jean-Pierre