XL 2013 [RÉSOLU] Transformation du temps : 10530 en 1:05:30

[Pascal-akka]

Bonjour
j'effectue des chronos et il est plus facile de taper un nombre au pavé numérique (ex : 10530) que de taper en format h:mm:ss (ex : 1:05:30)
Quelqu'un aurait-il une formule simple pour transformer A1=10530 en A2=1:05:30 ?

Merci d'avance de votre aide

 

[Fred0o]

Bonjour Pascal-akka et bienvenue sur le forum

Si le temps saisi se trouve en B2 :

=TEMPS(GAUCHE(B2;NBCAR(B2)-4);GAUCHE(DROITE(B2;4);2);DROITE(B2;2))

A tirer vers le bas

 

[Pascal-akka]

Bonjour Fred0o
La formule fonctionne à partir de 10000 (1h)
mais ne fonctionne pas si je tape 1 (1s) ou 100 (1mn) ==> #VALEUR!
As-tu (ou quelqu'un d'autre) une formule permettant aussi les nombres inférieurs à 10000 ?

 

[Victor21]

Bonjour, @Pascal-akka , @Fred0o 🙂

Essayez :

=(STXT(REPT("0";6-NBCAR(A1))&A1;1;2)&":"&STXT(REPT("0";6-NBCAR(A1))&A1;3;2)&":"&STXT(REPT("0";6-NBCAR(A1))&A1;5;2))*1

 

[Fred0o]

Voici la formule modifiée

=TEMPS(SI(NBCAR(B2)<4;0;GAUCHE(B2;NBCAR(B2)-4));SI(NBCAR(B2)<2;0;GAUCHE(DROITE(B2;4);2));DROITE(B2;2))

 

[Simply]

Bonjour

Cell Format
[>999]#\:##\:00;[>99]##\:00;00;@

 

[sylvanu]

Bonjour tout le monde,
Ou encore :

=(STXT(DROITE("000000"&B2;6);1;2)*3600+STXT(DROITE("000000"&B2;6);3;2)*60+STXT(DROITE("000000"&B2;6);5;2))/86400

En format Heure 13:30:55

 

[Pascal-akka]

Désolé Fred0o mais il y a une erreur dans ta formule
10505 donne 1:05:05 OK
505 donne 0:50:05 au lieu de 0:05:05 ???
5 donne 0:00:05 OK
10 donne 0:10:10 ???

Merci Victor21

=(STXT(REPT("0";6-NBCAR(A1))&A1;1;2)&":"&STXT(REPT("0";6-NBCAR(A1))&A1;3;2)&":"&STXT(REPT("0";6-NBCAR(A1))&A1;5;2))*1

ta formule fonctionne à merveille.

Merci à vous deux pour votre réactivité et la recherche de solution

 

[Efgé]

Bonjour à tous
Juste pour le plaisir
La même que Victor21 en plus courte

=(STXT(TEXTE(A1;"000000");1;2)&":"&STXT(TEXTE(A1;"000000");3;2)&":"&STXT(TEXTE(A1;"000000");5;2))*1

Cordialement