[Résolu]Plusieurs Si mais pas de résultats

[Thibault98]

Bonsoir à tous,

Voilà un bon moment que je fais des essais avec la fonction Si imbriquée pour obtenir un résultat mais je n'y arrive pas, je viens vous demander de l'aide et en même temps un exemple.

Je gère un troupeau, les mâles et les femelles dans le temps vont devenir Vaches ou Taureaux.

En jouant avec la "date du jour" je voudrais que dans la colonne C les noms changent, soit Mâle ou Femelle, soit Vache ou Taureau.

Je vous joint un classeur ou vous pourrez mieux comprendre.

Je vous remercie par avance.

Bonne soirée.

Thibault. 🙁

 

[R@chid]

Re : Plusieurs Si mais pas de résultats

Bonsoir,
Avec plusieures SI(), en C3,

=SI(D3="";SI(B3="M";"Male";"Femelle");SI(AUJOURDHUI()<=D3;SI(B3="M";"Male";"Femelle");SI(B3="M";"Toureau";"Vache")))

Je vais revenir réduire le nombre de SI() après la prière, c'est l'heure 🙂
@ + +

 

[JHA]

Re : Plusieurs Si mais pas de résultats

Bonsoir à tous,

A essayer,

=SI(B3="M";SI(ET(D3<>"";D3<=$H$2);"Taureau";"Mâle");SI(B3="F";SI(ET(D3<>"";D3<=$H$2);"Vache";"Femelle");""))

JHA

 

[R@chid]

Re : Plusieurs Si mais pas de résultats

Bonsoir @ tous,
J'ai réduit le nombre de SI(),
en C3,

=CHOISIR(1+NB(D3)*(H$2>D3)+(B3="F")*2;"Male";"Taureau";"Femelle";"Vache")

@ tirer vers le bas
@ + +

 

[Staple1600]

Re : Plusieurs Si mais pas de résultats

Bonjour à tous______________________________________________________EDITION: Salut job75 😉


Pour le fun, pour varier les façons de faire, pour le plaisir de croiser R@chid et JHA 😉
En utilisant une matrice "nommée" Genre et avec INDEX et le test logique de R@chid 😉
Donc au préalable, faire Insertion/Noms/Genre
voir copie écran

Ensuite formule avec INDEX à tester en colonne C

=INDEX(Genre;1+NB(D3)*(H$2>D3)+(B3="F")*2)

 

[job75]

Re : Plusieurs Si mais pas de résultats

Bonjour Thibault98, R@chid, JHA, Jean-Marie,

Cette formule "pèse" 95 octets :

=INDEX({"Mâle";"Femelle";"Taureau";"Vache"};1+(B3="F")+2*SIGNE(D3)*(H$2>D3))

La formule de R@chid "pèse" 111 octets :

=CHOISIR(1+NB(D3)*(H$2>D3)+(B3="F")*2;"Male";"Taureau";"Femelle";"Vache")

La fonction CHOISIR est gourmande en nombre d'octets.

Le fil pour "peser" les formules :

https://www.excel-downloads.com/threads/nombre-doctets-dune-formule-calcule-par-macro-vba.148601/

A+

 

[Thibault98]

Re : Plusieurs Si mais pas de résultats

Bonjour et merci à tous, j'ai essayé toutes vos formules elles sont toutes parfaites.

Un très grand merci, Bonne journée.

Thibault.

 

[job75]

Re : [Résolu]Plusieurs Si mais pas de résultats

Re,

Autre solution un peu plus maigre avec 85 octets :

=SUPPRESPACE(STXT("Mâle   FemelleTaureauVache  ";1+7*(B3="F")+14*SIGNE(D3)*(H$2>D3);7))

A+

 

[Thibault98]

Re : [Résolu]Plusieurs Si mais pas de résultats

Job75, vous êtes un pro ?

Génial !

@ bientôt
Thibault.