report mobile de feuille

[gbinforme]

report du solde mobile d'une feuille sur feuille suivante

bonjour à tous,

Un ami me demande de lui reporter un solde (dernière ligne d'une colonne)
sur la feuille suivante afin de constituer les 12 mois de l'année.
Bien sûr les feuilles sont de dimensions différentes selon les mois.
Je vous joins un exemple en fichier.

Je sais faire cela en créant la page par macro,
mais il ne veux pas utiliser de macros,
alors comment peut-on le faire avec une formule ?


Merci d'avance pour votre aide.

 

[Guillaumega]

Re : report mobile de feuille

bonsoir à vous, bonsoir au forum,

La formule suivante va chercher le solde du mois de janvier.

=RECHERCHE(9^9;'JANV 06'!H:H)

Bonne soirée,

 

[gbinforme]

report du solde mobile d'une feuille sur feuille suivante

bonsoir Guillaumega,

Merci pour la formule qui permet de trouver la dernière ligne,
mais j'aimerais aussi remplacer automatiquement le nom de la feuille
par le code "feuille précédente" que je ne connais pas.

Merci d'avance pour vos réponses.

 

[Guillaumega]

Re : report mobile de feuille

Re,

Les experts confirmeront mais je ne crois pas qu'il soit possible de faire cela sous excel. Il faudra faire du vba et l'intérêt est limité compte tenu de la facilité avec laquelle vous pourrez créer la formule... douze fois par an!

 

[Monique]

Re : report du solde mobile d'une feuille sur feuille suivante

Bonjour,

On peut le faire par formule.

Nom de l'onglet :
=STXT(CELLULE("filename";B10);TROUVE("]";CELLULE("filename";B10))+1;11)

Nom de l'onglet précédent :
=TEXTE(MOIS.DECALER(STXT(CELLULE("filename";B14);TROUVE("]";CELLULE("filename";B14))+1;11);-1);"mmmaa")

Dernière valeur numérique de la colonne H de la feuille précédente :
=RECHERCHE(9^9;INDIRECT(TEXTE(MOIS.DECALER(STXT(CELLULE("filename";H3);TROUVE("]";CELLULE("filename";H3))+1;11);-1);"mmmaa")&"!H:H"))

Pour pouvoir utiliser la fonction Mois.Decaler(), il faut activer l'utilitaire d'analyse dans Outils - Macros complémentaires et cocher "Utilitaire d'analyse"

En plus, le nom des onglets est à saisir en lettres minuscules, de façon à pouvoir mettre les accents en février, août et décembre.
En plus : pas d’espace entre le nom du mois et l’année.

Ou bien le nom de l’onglet en A1 et c’est plus court
=RECHERCHE(9^9;INDIRECT(TEXTE(MOIS.DECALER(A1;-1);"mmmaa")&"!H:H"))

 

[gbinforme]

Re : report mobile de feuille

Bonjour Monique,

Merci beaucoup de toutes ces formules très bien documentées.

C'est super, je vais pouvoir préparer l'année 2007 du classeur
avec aucun souci de report, sauf celui de 2006 mais il faut bien un départ.

Merci encore pour cette qualité de réponse.

J'essaierai de faire de même en VBA.

 

[solinari]

Re : report mobile de feuille

Pour poursuivre dans la même lignée, est-il possible de faire le report de déc08 à janv09 avec une fonction similaire à celle-ci?
Dans mon exemple le classeur reste le même d'année en année. De plus, je n'ai aucune crainte à utiliser VBA si nécessaire.
merci,
Soli

 

[Jiheme]

Re : report mobile de feuille

Bonjour le fil, le forum

Quel qu'un peut il m'expliquer le "9^9"

Merci

 

[jeanba]

Re : report mobile de feuille

bonsoir à vous, bonsoir au forum,

La formule suivante va chercher le solde du mois de janvier.

=RECHERCHE(9^9;'JANV 06'!H:H)

Bonne soirée,

Salut guillaumega,
je te tire mon chapeau parce là tu as fait très fort.
peux-tu m'expliquer le "9^9" s'il te plaît?
merci d'avance,
jeanba

 

[Monique]

Re : report mobile de feuille

Bonjour,

Solinari,
si le nom des onglets comporte aussi l'année, tu peux utiliser la même formule

En pièce jointe, le même fichier avec, en plus, le mois et l'année en A1 de chaque feuille