Microsoft 365 Renverser un tableau

D

D.D.

XLDnaute Impliqué

• 13 Juin 2023

• #2

J'ai trouvé quelque chose de simple, du genre:

VB:

=TRIERPAR(A1:A4;SEQUENCE(5;1;1;1);-1)

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 13 Juin 2023

• #3

Bonjour D.D.,

VB:

Sub Renverser()
Dim rc&, a, i
Application.ScreenUpdating = False
With [A1:A5]
    rc = .Rows.Count
    a = .Value
    For i = 1 To rc
        .Rows(i) = Application.Index(a, rc + 1 - i, 0)
    Next
End With
End Sub

A+

 

Vote positif 1 Vote négatif

A

ALS35

XLDnaute Impliqué

• 13 Juin 2023

• #4

Bonjour à tous,
Essaie :

VB:

=CHOISIRLIGNES(A1:A5;SEQUENCE(5;1;5;-1))

Le 5 est à adapter selon ta plage
Cordialement

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 16 Juin 2023

• #5

Bonjour le fil, @D.D. , @job75, @ALS35

Aprés la bataille
Avec 365, en spécifiant la plage
=TRIERPAR(A1:A5;LIGNE(A1:A5);-1)
Sans 365
=INDEX($A$1:$A$5;LIGNES(A1:$A$5))

Avec 365, sans spécifier la plage
=TRIERPAR(PRENDRE(A:A;NBVAL(A:A));LIGNE(PRENDRE(A:A;NBVAL(A:A)));-1)

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 17 Juin 2023

• #6

Bonjour à tous,
@Staple1600 : bien vu le TrierPar, et tant qu'à faire :

VB:

=LET(p;A1:A5;TRIERPAR(p;LIGNE(p);-1))

Cordialement

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 17 Juin 2023

• #7

Bonjour @ALS35

Comment éviter l'écueil des cellules vides ?
Car ceci
=LET(p;DECALER($A$1;0;0;NBVAL($A:$A);1);TRIERPAR(p;LIGNE(p);-1))
ou cela
=LET(p;PRENDRE(A:A;NBVAL(A:A));TRIERPAR(p;LIGNE(p);-1))
ne renverse pas toutes les données présentes en colonne A si il y a des trous.

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 17 Juin 2023

• #8

Bonjour à tous de nouveau,
Je pense que c'est dommage de prendre toute la colonne car de toutes façons tu ne veux renverser que la partie utile et pas les un million de lignes.
Un moyen d'améliorer en cas de cellules vides :

VB:

=LET(p;A1:A5;TRIERPAR(SI(p="";"";p);LIGNE(p);-1))

Cordialement

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 17 Juin 2023

• #9

Re

@ALS35
On s'est mal compris
Je voulais ne pas avoir à renseigner la plage dans la formule
D'où cette précision

Staple à dit:

Avec 365, sans spécifier la plage

Cliquez pour agrandir...

Je ne veux pas prendre toute la colonne mais la plage A1:Ax

Donc comment faire cela en formule ?
(Puisque mes essais du message#7 ne fonctionnent pas)

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 17 Juin 2023

• #10

Re,
Une tentative ?

VB:

=LET(p;INDIRECT("A1:A"&MAX(SI(A:A<>"";LIGNE(A:A);"")));TRIERPAR(SI(p="";"";p);LIGNE(p);-1))

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 17 Juin 2023

• #11

Re

@ALS35
Test OK

Mais avec celle-ci, Excel commence à ralentir 😉
=LET(p;FILTRE(INDIRECT("A1:A"&MAX(SI(A:A<>"";LIGNE(A:A);"")));NON(ESTVIDE(INDIRECT("A1:A"&MAX(SI(A:A<>"";LIGNE(A:A);""))))));TRIERPAR(SI(p="";"";p);LIGNE(p);-1))

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 17 Juin 2023

• #12

Re,
Et oui, une fonction volatile et toute une colonne, c'est pas bon pour le temps de réponse.
Un peu mieux quand même avec celle-ci ? (qui renverse et supprime les vides)

=LET(p;INDIRECT("A1:A"&MAX(SI(A:A<>"";LIGNE(A:A);"")));t;TRIERPAR(SI(p="";"";p);LIGNE(p);-1);FILTRE(t;t<>""))

Cliquez pour agrandir...

PS : ta fonction précédente ne renverse pas

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 17 Juin 2023

• #13

@ALS35

PS : ta fonction précédente ne renverse pas

Cliquez pour agrandir...

😉 sulp esrevner en no lecxE nom te iom ,duahc ,tiaf li dnauq ,eR

Avec celle-ci, ca renverse mais Excel tousse toujours un peu.

 

Vote positif 0 Vote négatif