Remplacer une cellule d'une colonne si elle est égale à plusieurs critères

[nimo]

Bonjour à Tous,

Je suis dans une nouvelle impasse,
J'aimerai programmer un code qui remplacer la valeur d'une cellule si elle est égale à une condition. Exemple:
si une cellule de la colonne U est égale à "jfk" ou "jbg" ou "lko" ou "jik" etc. (50 valeurs possibles)
alors remplacer cette cellule par "Pertinent"
Sinon "Impertinent"

Je l'ai fais via l'éditeur automatique mais du fait du nombre de valeur dans le ou, ca ,ne fonctionne pas...

J'éspère que quelqu'un aura une idée
Bonne soirée à tout le forum
Nimo

 

[Grand Chaman Excel]

Re : Remplacer une cellule d'une colonne si elle est égale à plusieurs critères

Bonjour nimo,

Voici une macro qui te permet de remplacer toutes tes cellules existantes dans la colonne U. Tu dois d'abord sélectionner les cellules à remplacer dans la colonne U et ensuite sélectionner une plage contenant tes valeurs de références (que tu peux écrire dans un autre onglet).

Sub Remplace()
    Dim rgRef As Range, rgSource As Range
    Dim c As Range, rgF As Range
    
    Application.ScreenUpdating = False
    
    Set rgSource = Application.InputBox("Cellule à vérifier : ", , , , , , , 8)
    Set rgRef = Application.InputBox("Plage de référence : ", , , , , , , 8)
    
    For Each c In rgSource
        Set rgF = rgRef.Find(c, lookat:=xlWhole)
        If rgF Is Nothing Then
            c = "Impertinent"
        Else
            c = "Pertinent"
        End If
    Next c

    Application.ScreenUpdating = True

End Sub

Si tu veux que le changement se fasse automatiquement quand tu entres une valeur dans la colonne U, il faudrait alors une macro événementielle qui se lance chaque fois que tu entres une valeur dans U.

A+