Microsoft 365 lister plusieurs valeurs correspondants à un critère

[saggigo]

Bonjour à vous les sauveurs 😀
J'ai vraiment besoin de votre aide si quelqu'un veut bien.

J'ai un tableau en deux colonnes, A et B. dans A il y a des noms qui se répètent, et dans B les scores pour chaque valeur dans A.

J'ai trouvé une formule avec INDEX/AGREGAT mais elle ne marche pas bien:
=SIERREUR(INDEX($E$2:$E$300;AGREGAT(15;6;(LIGNE($D$2:$D$300)-LIGNE($H4)+1)/($D$2:$D$300=H$2);LIGNE(H3)));"")

Ou H et la colonne ou je veux avoir la liste des pourcentage correspondants a une valeur de A. puis la colonne I pour les pourcentage d'un autre valeur dans A et ainsi de suite.

Je souhaite avoir un tableau qui me liste pour chaque valeur d'une cellule dans A tous les scores lui correspondants mais sans répétition du score

Voici mon tableau en pièce jointe....

Merci beaucoup vous etes geniaux

 

[mapomme]

Bonsoir @saggigo 🙂,

1) vos données comporte des valeurs d'erreurs. J'ai éliminé les lignes correspondantes (par fainéantise, je l'avoue - pas envie de compliquer la formule)
2) des pourcentages semblent identiques au niveau affichage mais à y regarder de plus près, ils peuvent différer par leurs décimales. J'ai donc arrondi les pourcentages à leur valeurs entières.

Dans ces conditions (pour O365), il y a une formule en E1 pour la liste des items :
=UNIQUE(A1:A218)

Et une autre formule en F1 (à copier vers la bas):
=TRANSPOSE(UNIQUE(TRIER(FILTRE(ARRONDI(B$1:B$218;2);(A$1:A$218=E1)))))

 

[saggigo]

AHHHH mapomme, c'est génial, ça marche 🙂 merci beaucoup, par contre a cause des petite erreur, j'ai un vide dans mon tableau. tu ne pourrais pas me dire comment l’enlever s'il te plait 😋😋😋😋😋

 

[mapomme]

Re @saggigo 🙂,

Une autre formule (O365) qui permet la présence d'erreurs dans la source.
Formule en F1 à copier vers le bas :
=TRANSPOSE(LET(FI;FILTRE(A$1:B$218;(NON(ESTERREUR(A$1:A$218&B$1:B$218))));TRIER(UNIQUE(ARRONDI(FILTRE(CHOISIRCOLS(FI;2);CHOISIRCOLS(FI;1)=E1);2)))))

 

[R@chid]

Bonjour @ tous,
une autre un peu plus courte, en F1 :

=TRANSPOSE(LET(Perc;TRIER(UNIQUE(ARRONDI(FILTRE(B:B;SIERREUR(A:A;)=E1);2)));PRENDRE(Perc;NB(Perc))))

@ tirer vers le bas

Cordialement

 

[saggigo]

Bonjour à vous et Merci @mapomme et @R@chid pour les réponses, vous êtes géniaux.

Je viens de me rendre compte qu'il manquait un paramètre dans mon approche 😖. je cherchais a extraire une info mais j'avais omis une entrée importante qui est la quantité des produits 🥴.

Donc finalement ce que je cherche c'est la moyenne d'un taux selon les quantités d'un produit🤔.

En fait j'ai un tableau qui contient plusieurs type produits qui se répètent, chaque ligne de produit a une quantité différente et chaque ligne a un pourcentage diffèrent. j'aimerais connaitre la moyenne de chaque type de produit selon les quantité. j'ai joint un exemple.

Et vraiment merci beaucoup beaucoup 😊

 

[JHA]

Bonjour à tous,

A essayer.

Si cela n'est pas le résultat escompté, peux-tu mettre sur le fichier les résultats attendus.

JHA

 

[saggigo]

Bonjour à tous,

A essayer.

Si cela n'est pas le résultat escompté, peux-tu mettre sur le fichier les résultats attendus.

JHA

Merci beaucoup pour ta réponse
En fait je souhaiterais avoir pour chaque type de produit ( sans répétition) la moyenne du pourcentage en fonction de la quantité
Par exemple :
Produit 1
Il y a 10 produits a 10%, 11 produits a 24%, et 15 produits a 10%, si la quantité était la meme il n'y aurait pas eu de soucis, mais c'est apparemment ce qu'on appelle la moyenne pondérée.

 

[JHA]

Bonjour à tous,

Peut-être

=SOMMEPROD(($A$2:$A$16=$K2)*(Tableau1[Qté]*Tableau1[Taux]))/[@Qté]

JHA

 

[saggigo]

Bonjour à tous,

Peut-être

=SOMMEPROD(($A$2:$A$16=$K2)*(Tableau1[Qté]*Tableau1[Taux]))/[@Qté]

JHA

Salut JHA,
Ca l'ai d'être ca mais j'ai un soucis avec la formule sur l'argument

[@Qté]

.... il me sort un message d'erreur

 

[JHA]

Bonjour à tous,

Tu peux essayer sur le tableau de droite en "N2"

=SOMMEPROD(($A$2:$A$16=$K2)*($B$2:$B$16*$C$2:$C$16))/$M2

JHA

 

[saggigo]

Bonjour à tous,

Tu peux essayer sur le tableau de droite en "N2"

=SOMMEPROD(($A$2:$A$16=$K2)*($B$2:$B$16*$C$2:$C$16))/$M2

JHA

Salut JHA,
Ca marche apparemment. je verifie 🙂

 

[saggigo]

Bonjour à tous,

Tu peux essayer sur le tableau de droite en "N2"

=SOMMEPROD(($A$2:$A$16=$K2)*($B$2:$B$16*$C$2:$C$16))/$M2

JHA

Merci beaucoup JHA, j'ai fini mon tableau grâce a toi 🥹

Le je suis sur un autre problème encore plus bizarre 🤣

Merci beaucoup, au plaisir.