Récupérer une donnée suivant 3 critères

[xavfer]

Bonjour,

j'aimerai récupérer sur un "tableau 1" une donnée provenant d'un "tableau 2", en tenant compte de 3 critères comme décrit ci-dessous :

tableau 1 (feuille 1)
colonne A : valeurs A, B, C
colonne B : date intervention

chaque valeur A, B, C peut apparaitre sur 1 ou plusieurs lignes suivant qu'elles sont associées à une ou plusieurs dates d'interventions

tableau 2 (feuille 2)
colonne A : valeurs A, B, C (les mêmes que celles de la liste initiale)
colonne B : date entrée
colonne C : date sortie
colonne D : LIEU

Comme dans tableau 1, chaque valeur A, B, C peut apparaitre sur 1 ou plusieurs lignes suivant qu'elles ont une ou plusieurs dates d'entrée (et sortie).

Pour des recherches de valeurs d'un tableau à l'autre sur une donnée j'utilise d'habitude la fonction RechercheV.
Mais ici, c'est une recherche plus complexe :
il faut récupérer la donnée "LIEU" (colonne D du tableau 2) sur le tableau 1, à condition que :
"date d'intervention" (tableau 1) >= à "date d'entrée (tableau 2)
ET
"date d'intervention" (tableau 1) <= à "date sortie" (tableau 2)

Comment peut-on faire ?
j'ai déjà essayé d'appliquer des solutions proposées pour des problèmes similaires mais je n'y parviens pas.
Merci de votre aide

 

[Dugenou]

Re : Récupérer une donnée suivant 3 critères

Bonjour Xavfer,

un petit fichier exemple aurait été pratique

voici un essai avec ce que j'ai compris

il y a un pb quand il y a plusieurs réponses possibles : on ne peut pas afficher plusieurs textes.

Cordialement

 

[xavfer]

Re : Récupérer une donnée suivant 3 critères

merci de votre aide, et désolé de ne pas avoir mis de fichier dès le début.
En voici un.
En fait il ne peut pas y avoir plusieurs réponses car les périodes (entrée/sortie) ne se juxtaposent pas pour une même valeur (ce que je n'ai pas précisé initialement).
En utilisant la formule avec mes données, je retrouve plusieurs erreurs.
Pouvez-vous revoir avec mon fichier ?
Merci encore

 

[Dugenou]

Re : Récupérer une donnée suivant 3 critères

Bonjour,

A coller en C2 et recopier vers le bas :
=INDEX(Feuil2!$D$1:$D$8;SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8)))

il faudra adapter les plages ...

Cordialement

 

[xavfer]

Re : Récupérer une donnée suivant 3 critères

Bonjour,

A coller en C2 et recopier vers le bas :
=INDEX(Feuil2!$D$1:$D$8;SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8)))

il faudra adapter les plages ...

Cordialement

merci, ça marche... sauf pour la ligne 8 (valeur B, intervention "10/02/2010").
La formule raméne une valeur fausse en C8 alors qu'il n'y a pas de donnée pour ce cas dans le tableau de la feuille 2.
Je cherche mais je ne comprends pas le problème.

 

[Dugenou]

Re : Récupérer une donnée suivant 3 critères

Bonjour,

voci la formule corrigée :
=SI(SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8))<=0;"";INDEX(Feuil2!$D$1:$D$8;SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8))))

quand on ne trouve rien : on affiche rien; l'erreur sur la ligne 8 est corrigée aussi (la formule (index(...;0) renvoiyait une valeur fausse mais pas une valeur d'erreur)

Cordialement

 

[xavfer]

Re : Récupérer une donnée suivant 3 critères

Bonjour,

voci la formule corrigée :
=SI(SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8))<=0;"";INDEX(Feuil2!$D$1:$D$8;SOMMEPROD((Feuil2!$A$2:$A$8=Feuil1!A2)*(Feuil2!$B$2:$B$8<=Feuil1!B2)*(Feuil2!$C$2:$C$8>=Feuil1!B2)*LIGNE(Feuil2!$A$2:$A$8))))

quand on ne trouve rien : on affiche rien; l'erreur sur la ligne 8 est corrigée aussi (la formule (index(...;0) renvoiyait une valeur fausse mais pas une valeur d'erreur)

Cordialement

C'est parfait, ça fonctionne très bien !
merci beaucoup de votre aide.
Bien cordialement