Récupération après dernier antislash

[Tony74]

Bonjour,
Je souhaite récupérer le nom des fichiers qui sont contenus dans un chemin mais je ne trouve pas comment faire.
Ex: C:\Temp\Dossier1\Dossier2\Fichier.txt
J'aimerai récupérer "Fichier.txt" dans la cellule d'à côté sachant que de nombreux chemins possibles.

D'avance merci pour votre aide

 

[pierrejean]

Bonjour Tony74

Avec une fonction personnalisée

 

[djidji59430]

Bonjour à tous,

Essaye :
=DROITE(E4;NBCAR(E4)-CHERCHE("$";SUBSTITUE(E4;"\";"$";4)))

avec C:\Temp\Dossier1\Dossier2\Fichier.txt en E4


Crdlmt

 

[Jocelyn]

Bonjour le Forum,
Bonjour tony74, l'ami pierrejean 🙂,

Principalement pour saluer notre camarade de jeu 🙂 , et accessoirement et pour le fun une solution par formule

=STXT(A1;CHERCHE("µ";SUBSTITUE(A1;"\";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;"\";""))))+1;99)

Cordialement

EDIT Bonjour djidji59430

 

[Lolote83]

Salut à tous,
Le temps de rafraichir et me voici déjà à la traine.
Voici donc mon code avant de jeter un coup d’œil aux vôtres
Formule personnalisée.
@+ Lolote83

 

[djidji59430]

j'ai retrouvé la bonne formule (dans mon répertoire de demandes bizarres-pour moi-):

{=DROITE(E4;EQUIV("\";STXT(E4;NBCAR(E4)-LIGNE($1:$99);1);0))}}

en matricielle

Salut a tous

 

[Lolote83]

Re salut à tous,
Une compilation des réponses ici car DjiDji n°1 n'était pas bonne
@+ Lolote83

 

[mapomme]

Bonsoir à tous,

Une autre formule :

=SUBSTITUE(DROITE(SUBSTITUE(C4;"\";REPT("\";256));256);"\";"")

 

[Tony74]

Wow!

Vous êtes géniaux, j'ai maintenant les 2 approches et c'est vraiment top!!
Merci à tous!

Belle journée