Microsoft 365 Reconstituer une liste

[Seydina]

Bonsoir le forum,
Je cherche à utiliser une liste de noms qui ne contiendrait que les 2 premiers mots.
Par exemple, "GROUPE NORMANDIE METALS UNITED" deviendrait "GROUPE NORMANDIE".
Dites moi si vous avez une solution
Seydina

 

[djidji59430]

Bonjour à tous,
=TEXTE.AVANT(E2;" ";2)

Crdlmt

 

[Gégé-45550]

Bonsoir le forum,
Je cherche à utiliser une liste de noms qui ne contiendrait que les 2 premiers mots.
Par exemple, "GROUPE NORMANDIE METALS UNITED" deviendrait "GROUPE NORMANDIE".
Dites moi si vous avez une solution
Seydina

Bonsoir,
essayez cette formule, à recopier vers le bas :

=SIERREUR(STXT(E2;1;TROUVE(CAR(1);SUBSTITUE(E2;" ";CAR(1));TROUVE(CAR(1);SUBSTITUE(E2;" ";CAR(1));1)+1));E2)

Cordialement,

[EDIT] Oups, pardon djidji59430, je n'avais pas vu ta réponse, plus concise mais utilisable seulement avec Office 365, avant de poster la mienne. [/EDIT]

 

[sylvanu]

Bonsoir à tous,
Ou encore avec :

=SIERREUR(STXT(E2;1;CHERCHE(" ";E2)+CHERCHE(" ";DROITE(E2;NBCAR(E2)-CHERCHE(" ";E2)))-1);E2)

 

[Seydina]

Bonsoir le forum,
Parfait pour les 2 solutions de Sylvanu et Gégé qui fonctionnent très bien.
Bravo

 

[djidji59430]

pas de reponse pour la mienne ? tu as pourtant excel 365 !!

Crdlmt

 

[jurassic pork]

Hello,
comme tu es en Office 365 tu dois pouvoir utiliser les expressions régulières. Tu peux essayer :

=REGEXEXTRACT(A1;"[^ ]+\s+[^ ]+")

explication du motif [^ ]+ un ou plusieurs caractères qui ne sont pas un espace \s+ suivi d'un ou plus caractères d'espacement [^ ]+ suivi d'un ou plusieurs caractères qui ne sont pas un espace.
Comme je n'ai pas Excel 365 j'ai essayé dans Excel OnLine 365 :

A noter qu'avec la formule de djidji59430 il y a une erreur avec ce texte :

Lefevre relecture/correction

car il n'y a pas de deuxième espace.

[EDIT] A noter aussi que quand il y a un seul mot la formule de Sylvanu renvoie ce mot tandis que
le Regex renvoie une erreur ce qui est logique puisque l'expression régulière n'est pas trouvée. si on veut le même comportement que la formule de Sylvanu il faut mettre :

=REGEXEXTRACT(A1;"[^ ]+\s*[^ ]*")

( * = 0 ou plus)
et à noter aussi que si il y a plusieurs espaces entre chaque mot la formule de Sylvanu ne fonctionne plus.
Et pour ceux qui n'ont pas excel 365 avec mon complément XlDnaLibJP la formule :

=REGEXEXTRACTJP(A1;"[^ ]+\s*[^ ]*";0)

Ami calmant, J.P

 

[Jean-Eric]

Bonjour,
Une autre proposition :

=SIERREUR(TEXTE.AVANT(E2;" ";2);E2)

 

[mapomme]

Bonjour à tous 🙂,

Une formule qui fonctionne s'il n'y a pas d'espace ni en tête ni en queue, s'il n'y a pas d'espaces multiples et même s'il n'y a qu'un seul mot voire en cas de chaine vide :
=GAUCHE(E2;CHERCHE(" ";SUBSTITUE(E2&" ";" ";CAR(1);1))-1)


Si le texte peut contenir des espaces (multiples ou non) en tête, au milieu ou en queue, alors préférez :
=GAUCHE(SUPPRESPACE(E2);CHERCHE(" ";SUBSTITUE(SUPPRESPACE(E2)&" ";" ";CAR(1);1))-1)

 

[mapomme]

Bonjour @jurassic pork 🙂 ,

Ta formule modifiée donne les mêmes résultats que ma 2ème formule (pour tenir compte du cas où A2 est vide et/ou si on a des espaces multiples) :
=SI(E2="";"";REGEX.EXTRAIRE(SUPPRESPACE(E2);"[^ ]+\s*[^ ]*";0))

nota: moi, je suis nul de chez nul en regex .

 

[Seydina]

Merci, je teste et reviens vers vous
Seydina

 

[Jean-Eric]

Re,
Une petite mise à jour avec les bottes , le parapluie, etc.
Cdlt.

=LET(txt;E2;a;SUBSTITUE(txt;CAR(160);CAR(32));b;EPURAGE(a);c;SUPPRESPACE(b);d;TEXTE.AVANT(c;CAR(32);2);SIERREUR(d;c))

 

[Jean-Eric]

Re,
Désolé, je n'avais pas vu la proposition initiale de djidji59430 !... 😳
Cdlt.

 

[Seydina]

Bonjour mapomme, le forum,
Parfait, ça va me faire gagner un temps considérable dans mes travaux.
Qu'est ce que vous êtes fort
Merci
Seydina