RECHERCHEV()

[luc]

Bonsoir,
Avec la formule RECHERCHEV() est-il possible d'afficher q'un seul caractere?
exp:
en A1 12346
en B2 en utilisant RECHERCHEV() on affiche que le 1.
Merci

 

[Monique]

Bonjour,

=GAUCHE(A1;1) ou GAUCHE(A1)
Si tu veux un résultat numérique et non du texte :
=GAUCHE(A1;1)*1

Si tu veux 2 caractères :
=GAUCHE(A1;2)
=GAUCHE(A1;2)*1

 

[luc]

Bonjour Monique,
Comment l'insérer avec la formule recherchev() ?
Merci.

 

[luc]

Le truc que je voudrais realiser:
dans la feuille1, cellule A1 12346
dans le feuille2, cellule B2 je voudrais un affichage de la sorte:1 2 3 4 6
avec la formule recherchev().
Merci.

 

[Monique]

Re,

C'est ton critère ou bien la valeur cherchée qui est le 1er caractère d'un nombre ?
Si c'est ton critère, j'ai fait quelques essais.

Tes nombres de A2 à A20
Tes valeurs recherchées en C2:C20
Recherchev classique, ce serait peut-être :
=RECHERCHEV("1";GAUCHE(A2:C20;1);3;0)
mais ça ne marche pas
Validé en matriciel, ça donne la 1ère lettre du mot de la 3è colonne

Avec Index Equiv :
=INDEX(C2:C20;EQUIV("1";GAUCHE(A2:A20;1);0))
à valider en matriciel, par ctrl, maj et entrée
Renvoie le mot de la 3è colonne

Si c'est la valeur cherchée :
=GAUCHE(RECHERCHEV(critère;A2:C20;3;0);1)
=GAUCHE(RECHERCHEV(critère;A2:C20;3;0))
=GAUCHE(INDEX(C2:C20;EQUIV(critère;A2:A20;0));1)
=GAUCHE(INDEX(C2:C20;EQUIV(critère;A2:A20;0)))

 

[Monique]

Aïe, je n'avais pas vu ton message

 

[Monique]

Re,

Recherchev, non.

En B2 de la feuille 2 :
=STXT(Feuil1!$A1;COLONNES($B2:B2);1)
à copier coller vers la droite
En B2, tu auras le 1er chiffre, en C2 tu auras le 2è, etc

=COLONNES($B2:B2) = 1
=COLONNES($B2:C2) = 2

 

[luc]

Merci Monique
Mais tout l'affichage doit se faire en B2 avec 3 ou espacements
Merci et bonne nuit.

 

[Monique]

Re,

La formule, mise dans la feuille 1 :
=STXT(A1;1;1)&" "&STXT(A1;2;1)&" "&STXT(A1;3;1)&" "&STXT(A1;4;1)&" "&STXT(A1;5;1)&" "&STXT(A1;6;1)&" "&STXT(A1;7;1)

Si tu coupes et colles dans une autre feuille, ça donne :
=STXT(Feuil1!A1;1;1)&" "&STXT(Feuil1!A1;2;1)&" "&STXT(Feuil1!A1;3;1)&" "&STXT(Feuil1!A1;4;1)&" "&STXT(Feuil1!A1;5;1)&" "&STXT(Feuil1!A1;6;1)&" "&STXT(Feuil1!A1;7;1)