Recherche dans un tableau selon 4 critères

[maxb]

Bonsoir à tous,
Malgré mes recherches, je n'ai pas trouvé de solution à ma situation.
J'ai 4 variables : age, genre, niveau et score. En définissant ces 4 variables (B1, E1, H1 et K1 dans le fichier d'exemple ci-joint), je souhaite trouver une formule qui me permette de d'afficher en N1 la donnée "norme" correspondante (en gris dans le tableau de D5 à M22).
J'ai déjà eu l'occasion d'utiliser la fonction RECHERCHEV pour des cas proches à 2 variables mais je ne trouve pas la formule pour 3 ou 4 variables.
Merci d'avance de vos aides et conseils.

 

[CISCO]

Re : Recherche dans un tableau selon 4 critères

Bonsoir

Tu peux faire avec

=INDEX(D5:M22;MIN(SI((A5:A22=B1)*(B5:B22=E1)*(C5:C22=H1);LIGNE(A5:A22)-4));EQUIV(K1;D4:M4;0))

en matriciel, à valider donc avec Ctrl+maj tempo+entrer

Si tu déplaces le tableau, il te faudra adapter le -4 en conséquence.

@plus

 

[Victor21]

Re : Recherche dans un tableau selon 4 critères

Bonsoir, maxb et bienvenue sur XLD.

Peut-être (validation matricielle ctrl+maj+entrée) :

=INDEX(D5:M22;EQUIV(B1&E1&H1;A5:A22&B5:B22&C5:C22;0);EQUIV(K1;D4:M4;0))

 

[CISCO]

Re : Recherche dans un tableau selon 4 critères

Bonsoir à tous, bonsoir Victor21

Ou encore

INDEX(D5:M22;MAX((A5:A22=B1)*(B5:B22=E1)*(C5:C22=H1)*(LIGNE(A5:A22)-4));EQUIV(K1;D4:M4;0))

toujours en matriciel

@plus

 

[Victor21]

Re : Recherche dans un tableau selon 4 critères

Re,

Ou en plus court, et sans validation matricielle mais avec une colonne supplémentaire (qui peut être masquée : ici colonne P) :

=DECALER($C$4;EQUIV(B1&E1&H1;P522;0);K1)

Voir pj

 

[maxb]

Re : Recherche dans un tableau selon 4 critères

Merci Victor21 et merci CISCO pour vos réponses (et avec quelle rapidité !). Ça fonctionne parfaitement !

 

[R@chid]

Re : Recherche dans un tableau selon 4 critères

Bonjour @ tous,
sans validation matricielle et sans colonne supplémentaire :

=INDEX(D5:M22;SOMMEPROD((A5:A22=B1)*(B5:B22=E1)*(C5:C22=H1);LIGNE(A5:A22)-4);K1)

@ + +

 

[CISCO]

Re : Recherche dans un tableau selon 4 critères

Bonjour

SOMMEPROD pour remplacer la validation matricielle, c'est pratique. K1 pour remplacer EQUIV(K1;...;0), c'est bien ici parce que les scores possibles correspondent exactement aux "n°" des colonnes, mais s'il en manque un... A utiliser avec prudence. Mais ici, dans le cas présent, c'est bien vu.

Bon W.E. à tous

@plus