recherche a plusieurs condition

[ghjunior]

Bonjour a tous, tout d'abord merci pour toutes les fois ou votre forum a pu m'aider.

ma question concerne une recherche avec plusieurs conditions j ai un peu de mal a exprimer ce que je voudrais faire, j'ai donc attaché en piece jointe le fichier sur lequel je travail pour essayer d être un peu plus clair. j'ai un colonne A avec le nom de la serie une colonne B avec un nombre et une collone F avec un autre nombre, jaimerais pouvoir trouver le nom de la colonne(dans la colonne A) qui correspond a: B= un certain nombre (que je pourrais changer quand je veux) et F compris entre 2 nombres. desolé d etre aussi incomprehensible :s

En gros concretement je voudrais pouvoir avoir le "port" qui correspond a une volatilité entre 2 chiffre et avec un montant fond € que je choisierais.

Merci beaucoup de votre aide potentiel

 

[Tibo]

Re : recherche a plusieurs condition

Bonjour,

Il aurait idéal que tu nous donnes le résultat attendu en fonction de l'exemple que tu nous as donné.

Avec ce que j'ai compris, avec une volatilité entre 3 et 4 et un fonds de 40, il me semble qu'il y a deux réponses possibles : port 15 et port 21

Lequel retenir ?

Et surtout, ai-je bien compris ?

A te (re)lire avec plus de détails

@+

 

[ghjunior]

Re : recherche a plusieurs condition

Oui tu as bien compris c est exactement ça.
je suppose que ce n'est pas possible que excel affiche les deux possibilitées?
Sinon simplement afficher l'une ou l'autre me suffirais puisque les recherche se feront avec des écarts de volatilité de 0.5 et il seras rare que cet exception se reproduise.
Par exemple avec une volatilité entre 3 et 3.5 et un fond euro de 40 je voudrais voir le port 15 s'afficher.

Merci de la rapidité de ta réponse.

 

[Tibo]

Re : recherche a plusieurs condition

re,

Un essai avec une formule matricielle :

=SI(SOMME(($F$2:$F$122>=$J$13)*($F$2:$F$122<=$K$13)*($B$2:$B$122=$J$15))=0;"Pas de réponse";INDEX($A$2:$A$122;EQUIV(1;($F$2:$F$122>=$J$13)*($F$2:$F$122<=$K$13)*($B$2:$B$122=$J$15);0)))

Formule matricielle à valider par CTRL + MAJ + ENTREE

Sinon, il est possible d'afficher les deux solutions avec une formule (également matricielle)un peu plus complexe.

@+

 

[ghjunior]

Re : recherche a plusieurs condition

ça marche! tu es vraiment très fort! je voudrais bien aussi celle qui affiche les deux solutions si ça ne te dérange pas trop.

 

[Tibo]

Re : recherche a plusieurs condition

re,

La formule pour gérer le cas où il y aurait plusieurs réponses possibles :

=SI(LIGNES($1:1)>SOMME(($F$2:$F$122>=$J$13)*($F$2:$F$122<=$K$13)*($B$2:$B$122=$J$15));"";INDEX($A$1:$A$122;PETITE.VALEUR(SI(($F$2:$F$122>=$J$13)*($F$2:$F$122<=$K$13)*($B$2:$B$122=$J$15)*LIGNE($A$2:$A$122)>0;($F$2:$F$122>=$J$13)*($F$2:$F$122<=$K$13)*($B$2:$B$122=$J$15)*LIGNE($A$2:$A$122));LIGNES($1:1))))

Toujours matricielle, donc validation par CTRL + MAJ + ENTREE

à recopier vers le bas.

Je te laisse tester.

@+

 

[ghjunior]

Re : recherche a plusieurs condition

ça fonctionne. C'est exactement ce dont j'avais besoin merci beaucoup.

@+

 

[Monique]

Re : recherche a plusieurs condition

Bonjour,

Ou bien

En J18 :

=INDEX($A1:$A122;MIN(SI(($F2:$F122>=$J13)*($F2:$F122<=$K13)*($B2:$B122=$J15)*(NB.SI($I18:I18;$A2:$A122)=0);LIGNE($A2:$A122))))

Formule matricielle, à valider par ctrl, maj et entrée

Copier et coller sur K18

Format personnalisé de la cellule :
[=0]"Pas de réponse";Standard

 

[ghjunior]

Re : recherche a plusieurs condition

merci Monique.